next if $text =~ /^\.+$/;
[download]

(untested)

NB: this will also exclude files consisting of dots only.

otherwise

next if $text =~ /^\.\.?$/;
[download]

What would be a solution to get rid of those dots?

use warnings;
use strict;
use File::Slurp qw(read_dir);

for my $file (read_dir('.')) {
    print "$file\n";
}
[download]

Unfortunately, the perl version we need to use is about 8 years old, and doesn't have the File library in it, so can't use tht :(

. is "the current directory" and .. is "the parent directory". File::Spec provides the functions no_upwards, curdir and updir to help deal with them.

#!/usr/bin/env perl
use warnings;
use strict;
use File::Spec::Functions qw/no_upwards curdir updir/;
my $DIR = "/tmp/foo";
opendir my $dh1, $DIR or die $!;
while(my $text = readdir $dh1) {
    next if $text eq updir || $text eq curdir;
    print "1: $text\n";
}
closedir $dh1;
opendir my $dh2, $DIR or die $!;
my @files = no_upwards readdir $dh2;
closedir $dh2;
print "2: $_\n" for @files;

__END__

1: File.txt
2: File.txt
[download]

I'm still endorsing IO::All:

#!/usr/bin/env perl

use strict;
use warnings;
use IO::All;
use feature qw(say);

say for io('myDir')->all;

__END__

karls-mac-mini:monks karl$ mkdir myDir

karls-mac-mini:monks karl$ touch myDir/File.txt

karls-mac-mini:monks karl$ ls -al myDir/
total 0
drwxr-xr-x    3 karl  karl    102  6 Mär 18:38 .
drwxr-xr-x  410 karl  karl  13940  6 Mär 18:44 ..
-rw-r--r--    1 karl  karl      0  6 Mär 18:38 File.txt

karls-mac-mini:monks karl$ ./1119062.pl
myDir/File.txt
[download]

From the docs:

all (For directories)
Returns a list of IO::All objects for all files and subdirectories in 
+a directory.

'.' and '..' are excluded.
[download]

Regards, Karl

for (glob('*')) {
   print "$_\n";
}
[download]

opendir(my $dh, '.') or die $!;
for ( grep { !/^\.+$/ } readdir $dh ){
   print "$_\n";
}
[download]

On a Windows system, glob gave me huge fits of incorrect results in early versions of ActiveState Perl, leading me to write my filenames.pm. When CPAN modules came out, they got increasingly closer to the goal, but still kept missing the mark.

In those days, I was unable to devote time to working on taking my lessons learned in the writing of my filenames.pm module and applying them to the various CPAN modules (a recurring theme for me during that era of my career, unfortunately), so I grew into habitual use of my own module.

In retrospect, I wish I'd gotten more involved in CPAN modules instead of rolling my own all the time; I'd have a much better toolkit at my disposal now, and as an added benefit I'd probably be better and faster at installing CPAN modules on the rare occasion where I find one could save me some development time.

Ah, the heady days of youth.

Otherwise you may filter out directories and keep only files:

opendir my $dh, $dirname or die "could not open $dirname $!";
print "$_\n" for grep { -f $_ } readdir $dh ;
[download]

BTW, Path::Class, Path::Tiny, File::Find and File::Find::Rule all ignore those two directory entries by default. They're usually much easier to use than raw readdir.