Have you looked at the various implementations of the assert keyword on CPAN?

There are a lot of them; could you please specify the most prominent?

As for the modules I've managed to look into, for instance Carp::Assert, they seem to focus on optimizing themselves away in production.

I think this could be a valuable future option for my module. However, this is not the main point of it.

For now, it's more about providing a way to actually impose limitations on the way code works in both development and production. Optimisation is for later...

I guess I'm not really sure what your use case is.

If your code is mostly object-oriented, you can take advantage of type constraints in any of the major OO frameworks. That automatically covers you for object constructors and accessors.

Then if you want to check the parameters passed to method calls and function calls, you can re-use the same type constraint checking, courtesy of things like Type::Params. For example, if you want to check that your add function has been passed two numbers:

use feature qw(state); # Perl 5.10+
use Type::Params qw(compile);
use Types::Standard qw(Num);

sub add {
  state $check = compile( Num, Num );
  my ($x, $y) = $check->(@_);  # will croak if not passed two numbers
  
  my $sum = $x + $y;
  
  return $sum;
}
[download]

If you want to check that certain variables are sane within your function, not just the parameters that are passed as input, then you can still do this with type constraints:

use feature qw(state); # Perl 5.10+
use Type::Params qw(compile);
use Types::Standard qw(Num);

sub add {
  state $check = compile( Num, Num );
  my ($x, $y) = $check->(@_);  # will croak if not passed two numbers
  
  my $sum = $x + $y;
  
  Num->assert_return( $sum );
}
[download]

Though frankly, if you keep your function definitions short and simple, this is rarely necessary.

Then you just come down to a handful of sanity checks that go beyond what type constraints would normally do.

use feature qw(state); # Perl 5.10+
use Type::Params qw(compile);
use Types::Standard qw(ArrayRef);
use Carp;
use PerlX::Assert;

sub zip {
  state $check = compile( ArrayRef, ArrayRef );
  my ($x, $y) = $check->(@_);
  
  # An additional check on input.
  # Carp is a pretty appropriate way of dealing with this.
  #
  croak "Arrays must be same length" unless @$x == @$y;
  
  my @z = map {  [$x->[$i], $y->[$i]]  } 0 .. $#$x;
  
  # These assertions check the internal logic of our
  # function, so using Carp makes less sense. It's not
  # the caller's fault if they fail. Here an assertion
  # feature makes sense. And because we believe
  # our logic to be correct, it's hopefully okay to
  # optimize this away in the production environment.
  #
  assert '@z has same length as @$x' { @z == @$x };
  assert '@z has same length as @$y' { @z == @$y };
  
  # \@z should be an arrayref of arrayrefs.
  #
  ArrayRef->of(ArrayRef)->assert_valid( \@z );
}
[download]

I don't see what the point of adding a big Test::Builder-like framework on top of this would be. What can it cover which the above cannot?

• Added configurable runtime assertions via refute_these{ # ok, like here }; # warns if not pass;
• Separated contract definitions from contract reports;
• Builder builds subs that run just fine both as runtime assertions and under Test::More;
• Own unit-testing engine was withheld.

With DbC, contracts are actually part of the code, not secondary constructs like unit tests. Contracts and unit tests are different, 'orthogonal' ways of verifying code. Contracts can be enabled/disabled at run time, and you wouldn't test the contract as such, though you could have tests that exercise typical workflows and contract violations would show up as exceptions being raised.

Also contracts in this sense are not meant to validate data, but to verify an object API is working as agreed.

Some modules that support DbC: Class::Contract, MooseX::Contract.

Hello Arunbear,

I probably didn't at the time of the grandparent post, but I did look it up since and abandoned contract in the name for good.

I don't think what I want is full-fledged DbC though. It's a bit "take it or leave it" - adding it to just some subs looks silly and adding it throughout an (already working) project seems like a bit of overkill and also a big and risky task.