#!/usr/bin/perl 
use strict;
use warnings;


open my $fh, '<',"human_hg19_circRNAs_putative_spliced_sequence.fa",or
+ die $!;

my %id2seq;

    while(<$fh>){
        my $id = '';
        chomp;
        if($_ =~ /^>(.+)/){
            $id = $1;
        }else{
            $id2seq{$id} .= $_;
        }
    }

 

    foreach my $id (keys %id2seq){
        my $filename = (split /\|/, $id)[0];
        open  my $out_fh, '>>', "$filename" or die $!; 
        print $out_fh ">".$id."\n",$id2seq{$id}, "\n";
        close $out_fh;
    }


close $fh;
[download]

How do I integrate the value I've split and extracted into the naming of the file, because it's stating that it's uninitialised?

Although, I thought that it was clearly initialised/defined here:

  my $filename = (split /\|/, $id)[0];
        open  my $out_fh, '>>', "$filename" or die $!;
[download]

Or maybe I'm just misunderstanding the scope? Where do I place the $filename in the loop?

Pete.

The problem is earlier where $id is set for the > lines but then cleared on the subsequent sequence lines

while(<$fh>){
  my $id = '';
  chomp;
  if ($_ =~ /^>(.+)/){
    $id = $1;
  } else {
    $id2seq{$id} .= $_;
  }
}
[download]

Try

#!/usr/bin/perl 
use strict;
use warnings;

my $id;
my %id2seq;

my $infile = 'human_hg19_circRNAs_putative_spliced_sequence.fa';
open my $fh,'<',$infile 
     or die "Could not open $infile : $!";
while (<$fh>){
  if ( /^>(.+)/ ){
    $id = (split /\|/, $1)[0];
  }
  $id2seq{$id} .= $_;
}

foreach my $id (keys %id2seq){
  my $filename = $id.'.fa';
  print "Creating $filename\n";
  open my $out_fh,'>', $filename 
       or die "Could not open $filename : $!";
  print $out_fh $id2seq{$id};
  close $out_fh;
}

close $fh;
[download]

poj

Did you try printing the values of your variables as I suggested?



The way forward always starts with a minimal test.

Yes, I tried it and got the following:

ID: at seqextractor.pl line 23, <$fh> line 130.

Segments: $VAR1 = [];

From the using the following

foreach my $id (keys %id2seq){
         warn "ID: $id";
  my @segments = split /\|/, $id;
       warn "Segments: " . Dumper \@segments;
       my $filename = $segments[0];
       
    }
[download]

Does it mean that the array is empty?

If I use your method surely I will not be able to print the full fasta sequence title followed by a newline and then the sequence in my newly created file, because $id will become (hsa_circ_0000001), whereas I need to be able to capture both (hsa_circ_0000001) and (>hsa_circ_0000001|chr1:1080738-1080845-|None|None) and apply them seamlessly as the new files are created in my loop.

Pete.

If so create a new variable for the filename, just before creating the file, as in

 

foreach $id (keys %id2seq){
                 # here the last good possibility to cut $id:
                 my $filename = (split /\|/, $id)[0];
                 ...
[download]

L*

There are no rules, there are no thumbs..
Reinvent the wheel, then learn The Wheel; may be one day you reinvent one of THE WHEELS.

Thank you for this advice,it's golden, I will try to implement all your points today.

Pete.

Okay, so I tried to implement that as so:

    foreach $id (keys %id2seq){
        my $filename = (split /\|/, $id)[0];
        open  my $out_fh, '>>', "$filename.fa" or die $!; 
        print $out_fh (">".$id."\n",$id2seq{$id}, "\n");
        close $out_fh;
    }
[download]

So I'm just trying to figure out where I should be declaring  $filename

Pete.

First, follow the advice given. Go through your script and correct *all* the items Discipulus pointed out. Second, when in doubt, print out the value of your variables.

use Data::Dumper;
...
foreach my $id (keys %id2seq) {
    warn "ID: $id";

    my @segments = split /\|/, $id;
    warn "Segments: " . Dumper \@segments;

    my $filename = $segments[0];

    ...
}
[download]

Once the code is working right, remove the debug statements.


The way forward always starts with a minimal test.

No, you got the error saying that $filename.fa is uninitialized.
So perl saw that as a variable name while you intended to only use $filename instead.
In order to delimit the variable name you can use this syntax: "${filename}.fa".
Good luck, hexcoder

No, you got the error saying that $filename.fa is uninitialized. So perl saw that as a variable name ...

Sorry, but that's not correct in this case, a dot does end the variable name being interpolated. As the OP is using strict, that would have caught the error anyway. Your advice does apply for other characters though.

$ perl -wMstrict -le 'my $fn="x"; print "$fn.y"'
x.y
$ perl -wMstrict -le 'my $fn="x"; print "$fn_y"'
Global symbol "$fn_y" requires explicit package name (did you forget t
+o declare "my $fn_y"?) at -e line 1.
Execution of -e aborted due to compilation errors.
$ perl -w        -le 'my $fn="x"; print "$fn_y"'
Name "main::fn_y" used only once: possible typo at -e line 1.
Use of uninitialized value $fn_y in string at -e line 1.
$ perl -wMstrict -le 'my $fn="x"; print "${fn}_y"'
x_y
[download]