it could cause unintended and confusing side effects

It's of course a matter of opinion, but I do agree with this - it's a neat but somewhat obscure use of glob. It can be useful, as it allows one to generate combinations using just core Perl, without loading e.g. Algorithm::Combinatorics. But all it takes is someone who doesn't know the details ("If non-empty braces are the only wildcard characters used ...") or the interpolation of unchecked variables into the pattern for it to break. Personally, my feeling is that in a one-off script, or with a fixed string plus a comment warning future maintainers, it's ok to use. But if you want to play it safe with respect to future maintainers, I'd avoid it.

As for using <a b c> as a replacement for qw/a b c/, sure it's clever, but IMO it's a silly place to save two characters, and I'd probably recommend against it. Also, I like to use File::Glob ':bsd_glob';, which breaks it:

$ perl -le 'print for <a b c>'
a
b
c
$ perl -MFile::Glob=:bsd_glob -le 'print for <a b c>'
a b c
[download]

I also use ':bsd_glob'. I could show how if I use a function someone else potentially creates using glob to create an array it would quit working with bsd_glob. Thanks.

Update: demo code.

use strict;
use warnings;
use Data::Dumper;
use File::Glob ':bsd_glob';

my @arr1 = get_list1();
print Dumper(\@arr1);

my @arr2 = get_list2();
print Dumper(\@arr2);

sub get_list1 {
    return < abc def ghi >;
}
sub get_list2 {
    return qw( abc def ghi );
}

__DATA__

$VAR1 = [
          ' abc def ghi '
        ];
$VAR1 = [
          'abc',
          'def',
          'ghi'
        ];
[download]

I find the phrase "If non-empty braces are the only wildcard characters used in the glob" misleading because it makes it sound like there are many wildcard chars to choose from, rather than just * and braces. So that would be "If there is no * in the glob". You also demonstrated that even if there are * in the strings, it can potentially return strings without matching files, because glob("PATTERN_A PATTERN_B") is the same as (glob("PATTERN_A"), glob("PATTERN_B")).

That said, the other difference between glob and qw is interpolation, and quotes. You can't have an element with a space inside qw, but you can in glob. And glob interpolates while qw does not. IIRC ruby has each quoting construct in pairs, interpolating or non interpolating, so you can insert a few variables in a list of words. glob is tricky though, because interpolation is done first, and spaces and quotes in your variables might not do what you want:

use Data::Dump qw( pp );

my $interpolate = "A";
my $trap = "'X Y' Z";

pp qw( $interpolate B 'C D' "E F" $trap); 
pp < $interpolate B 'C D' "E F" $trap \Q$trap>;

__DATA__
("\$interpolate", "B", "'C", "D'", "\"E", "F\"", "\$trap")
("A", "B", "C D", "E F", "X Y", "Z", "'X\\ Y'\\ Z")
[download]

So as a conclusion: qw works exactly like a single quoted string splited on whitespace, but glob can be tricky if braces, *, $, @ or quotes are present in the string. Also qw accepts newlines where glob doesn't.

I find the phrase "If non-empty braces are the only wildcard characters used in the glob" misleading because it makes it sound like there are many wildcard chars to choose from, rather than just * and braces.

There are a few other meta characters for glob().

META CHARACTERS
1.  \       Quote the next metacharacter
2.  []      Character class
3.  {}      Multiple pattern
4.  *       Match any string of characters
5.  ?       Match any single character
6.  ~       User name home directory
[download]

Meh, I stopped at the glob documentation and didn't go any further. Well then, that's a whole bunch of characters to avoid :).

/me learned something new about perl today. Thanks :)

Edit: the list is in File::Glob for anyone who is wondering.