Quick and dirty, check if you're at the end of file:

use warnings;
use strict;

open my $fh, '<', 'file.txt'
  or die "can't open the damned file!: $!";

while (<$fh>){
    chomp;

    if (! eof){
        print "$_,\n";
    }
    else {
        print "$_\n";
    }
}
[download]

Where 'file.txt' contains:

one
two
three
[download]

Output:

one,
two,
three
[download]

Another way to do this is with the join function, which lets you avoid appending the final comma in the first place.

Read the data from your file, split it on whitespace, join each datum with commas, and surround the entire record with parentheses:

foreach my $line (<$infh>) {
    if ($line =~ /$re_data/) {
        # Split on whitespace, surround with parens, join with commas
        push @data, "(" . join(",", split(/\s+/, $line)) . ")";
    }
}
[download]

and finally, join the records with a comma followed by a newline. The last record won't get a comma (nor newline):

# Simply 'join' all data; last record contains neither comma nor newli
+ne.
my $data = join(",\n", @data);
[download]

Here's an entire working example:

#!/usr/bin/perl

use strict;
use warnings;
use feature qw( say );
use IO::File;


##################
## User-defined ##
##################
my $input   = 'in.txt';       # Input file
my $output  = 'out.txt';      # Output file
my $re_data = qr/^[0-9]+/;    # Detect lines containing records

##################
## Main program ##
##################
# Read the input
my $infh = IO::File->new($input) or die "Can't read '$input' ($!)";
my @data = ( );

foreach my $line (<$infh>) {
    if ($line =~ /$re_data/) {
        # Split on whitespace, surround with parens, join with commas
        push @data, "(" . join(",", split(/\s+/, $line)) . ")";
    }
}
close($infh);

# Simply 'join' all data; last record contains neither comma nor newli
+ne.
my $data = join(",\n", @data);

# Create the output
my $text = qq{
    SELECT CUSTOMERID, ORDERID, CUSTOMERNAME, CUSTOMERLOCATION
    FROM DB.CUSTOMER_DATA
    WHERE (CUSTOMERID, ORDERID, CUSTOMERNAME, CUSTOMERLOCATION) IN (
      $data
    )
};
$text =~ s/\n\s+/\n/g;    # Remove indentation (for "looks")

# Write the output
my $outfh = IO::File->new;
open($outfh, '>', $output) or die "Can't write '$output' ($!)";
print $outfh $text;
close($outfh);
say "Wrote '$output'";
[download]

The output for which is:

SELECT CUSTOMERID, ORDERID, CUSTOMERNAME, CUSTOMERLOCATION
FROM DB.CUSTOMER_DATA
WHERE (CUSTOMERID, ORDERID, CUSTOMERNAME, CUSTOMERLOCATION) IN (
(0001,20000001,john,CA),
(0002,30000002,neill,WI),
(0003,40000003,joe,GA),
(0004,50000004,will,IL),
(0005,60000005,mike,IN),
(0006,70000006,bill,AK)
)
[download]

This works nice

Had to ditch the +ne from the code and then all worked nicely




Thanks once more

Hi luupski,

I'm not seeing it, but I guess the "+ne" (where "+" is colored red) is a continuation (word wrap) of the comment which ends with:

# ... last record contains neither comma nor newline.
[download]

You can avoid it by changing increasing the code wrap length in your User Settings or turning off code wrapping.

Alternatively, you click on any [download] link; these take you to an unadulterated rendering of the text. (This is true for any node containing code samples).

say  substr+lc crypt(qw $i3 SI$),4,5

Thank you golux, going to give this a try

Which database is this, MySQL ? Don't the text values need to be in quotes ?

You could also try fixing on a later step. Put the following small Perl script into chop-sql-comma.pl:

my $sql = do {local $/; <>};
$sql =~ s/\( ([^()]+) \) , \n\)/($1)\n)/x;
print $sql;
[download]

Then run from a command prompt with perl "edit in place" mode:

C:\Users\...>perl -i.bak chop-sql-comma.pl CUSTOMER_NEW.txt
[download]

Update - after some more digging golfed to (again windows cmd prompt):

perl -Mv5.14.0 -i.bak -e^
 "local $/;print <> =~ s/\( ([^()]+) \) , \n\)/($1)\n)/xr"^
  CUSTOMER_NEW.txt
[download]

Thnx Ron, will give this a run as well

This is for an Oracle Database