Sorry, but I don't understand the question.

• You haven't provided any sample input data, or the expected output for that input. See also How do I post a question effectively? and I know what I mean. Why don't you?
• Please use consistent indentation in your source code. See perltidy to help with that.
• Please provide a Short, Self-Contained, Correct Example: for example, the code from open (my $in ... up to close $it ; doesn't seem to have anything to do with counting words, and the last two blocks of code beginning with my $numlinepw and my $numlinenw seem to be pretty much identical except for the variable names, for the purposes of asking this question one of them can be removed, and in the final code should probably be refactored into a subroutine.

Having said all that, this looks suspicious to me: @nwords = split( /\n/, $nwt ); - @nwords will contain lines, not words, unless of course your input file only has one word per line - but again, you haven't shown it, so we don't know. (Update: And it's not just that - $nwt is a filehandle, as per jwkrahn's post).

Given what wise haukex already said and considering only your title, a simple oneliner can do the task (pay attention to windows double quotes):

perl -lne "$count+=split}{print $count" /path/file1 /path/file2
[download]

Using Deparse can give you a working starting point to work with:

perl -MO=Deparse -lne "$count+=split}{print $count"  /path/file1 /path
+/file2

BEGIN { $/ = "\n"; $\ = "\n"; }
LINE: while (defined($_ = readline ARGV)) {
    chomp $_;
    $count += split(' ', $_, 0);
}
{
    print $count;
}
-e syntax OK
[download]

That can be translated in: foreach file in the input ( see ARGV in perlodoc ) read it line by line, chomp each line, split the line at withespaces and add the resulting word count to $count When all file processing is finished print the value of $count

L*

Here's an alternative:

perl -ne 's/\W+/$i++/eg;END{print "$i\n"}' f1 f2
[download]

Hi kschwab,

Are you sure? This one gives the same result like wc.

perl -ne 's/\S+/$i++/egi;END{print "$i\n"}' f1 f2
[download]

open (my $inwp , "<:encoding(utf8)" , "$pwt") or die "$pwt: $!" ;
while (<$inw>) {

my @pwords ;
my @ptw ;
my $elementp ;
my $countp ;

  @pwords = split (/\n/ , $inwp) ;
[download]

The variable $inwp is a FILEHANDLE and does not contain any data from the file $pwt.

open (my $nwt , "<:encoding(utf8)" , "$ntw" ) or die "$ntw: $!" ;

while (<$itw>) {

  $numlinenw++ ;

my @nwords ;
my @ntw ;
my $elementn ;
my $countn ;


@nwords = split (/\n/ , $nwt) ;
[download]

The same thing with the variable $nwt.

Hi bro

i have 2 files that include a lot of sentences and also i have 2 files include negative words and positive words and i want to count the number use of these 2 type of words in the sentences , my sentences are $pt = '/root/Positive.txt' , $nt = '/root/Negative.txt' so my words are $pwt = '/root/Positive2.txt' , $ntw = '/root/Negative2.txt' , now i want to count the number of words in 2 sentences by this code

Here's an example of counting defined sets of "words" (which can be tricky to define) based on the technique described in the Building Regex Alternations Dynamically article by haukex. If you can figure out how to get the contents of your positive and negative word data files into the corresponding arrays (and if my notion of what you want is anywhere near what you actually want), you may be on your way.

Note that the code is set up for case-insensitive matching and counting: the negative word "fourscore" matches "FoUrScOrE" in the example sentence, and so on. Note, again, that the concept of a "word" can be slippery, so the use of the  \b boundary assertion, among other details, may not be appropriate.

c:\@Work\Perl\monks>perl -wMstrict -MData::Dump -le
"my @positive = qw(nation conceived liberty created equal foo);
 my @negative = qw(fourscore SEVEN fOrTh fathers continent bar);
 ;;
 my $sentence = 'FoUrScOrE and seven years ago '
              . 'our fathers brought forth, on this continent, '
              . 'a new nation, conceived in liberty, and dedicated '
              . 'to the proposition that all men are created equal. '
              . 'Repeat seven nation fathers nation.'
              ;
 ;;
 my %pos = map { lc($_) => 0 } @positive;
 my $rx_pos = make_regex(\%pos);
 print 'for debug: positive rx: ', $rx_pos;
 ;;
 my %neg = map { lc($_) => 0 } @negative;
 my $rx_neg = make_regex(\%neg);
 print 'for debug: negative rx: ', $rx_neg;
 ;;
 my %other;
 my $rx_undefined = qr{ (?! $rx_pos | $rx_neg) }xms;
 my $rx_word      = qr{ \b [[:alpha:]]+ \b }xms;
 ;;
 ++$pos  { lc $_ } for $sentence =~ m{ $rx_pos }xmsg;
 ++$neg  { lc $_ } for $sentence =~ m{ $rx_neg }xmsg;
 ++$other{ lc $_ } for $sentence =~ m{ $rx_undefined $rx_word }xmsg;
 ;;
 dd \%pos;
 dd \%neg;
 dd \%other;
 ;;
 ;;
 sub make_regex {
   my ($hr_wordlist) = @_;
   ;;
   my ($rx) =
     map  qr{ (?i) \b (?: $_) \b }xms,
     join '|',
     map  quotemeta,
     reverse sort
     keys %$hr_wordlist
     ;
   ;;
   return $rx;
   }
"
for debug: positive rx: (?msx-i: (?i) \b (?: nation|liberty|foo|equal|
+created|conceived) \b )
for debug: negative rx: (?msx-i: (?i) \b (?: seven|fourscore|forth|fat
+hers|continent|bar) \b )
{ conceived => 1, created => 1, equal => 1, foo => 0, liberty => 1, na
+tion => 3 }

{ bar => 0, continent => 1, fathers => 2, forth => 1, fourscore => 1, 
+seven => 2 }

{
  a           => 1,
  ago         => 1,
  all         => 1,
  "and"       => 2,
  are         => 1,
  brought     => 1,
  dedicated   => 1,
  in          => 1,
  men         => 1,
  new         => 1,
  on          => 1,
  our         => 1,
  proposition => 1,
  repeat      => 1,
  that        => 1,
  the         => 1,
  this        => 1,
  to          => 1,
  years       => 1,
}
[download]

Update: In the  make_regex() function, the lines
    reverse sort
    map  quotemeta,
are swapped | were swapped (fixed); they should be
    map  quotemeta,
    reverse sort
i.e., sort-ing, either lexically or by length, should be done on the raw strings before the quotemeta step.

---

Give a man a fish:  <%-{-{-{-<