How about:

use POSIX 'strftime';
my $clear = $^O =~ m/Win32/ ? 'cls' : 'clear';
while ( 1 ) {
    system $clear;
    @digits = split '', strftime("%H%M%S", localtime);
    print '  ', @digits, "\n  ------";
    for my $bin ( 8,4,2,1 ) {
        print "\n$bin ";
        for my $digit ( @digits ) {
            $digit >= $bin ? do {$digit -= $bin; print "\052"} : print
+ "\117" ; 
            # print $bin & $digit ? 1 : 0; # could use binary and to s
+elect
        }
    }
    sleep 1;
}

# this will show you all the possible octal char codes you might like 
+to use
printf "\\%03o\t %s\n", $_, chr for 40..255;
[download]

cheers

tachyon

s&&rsenoyhcatreve&&&s&n.+t&"$'$`$\"$\&"&ee&&y&srve&&d&&print

my $time = sprintf '%02d0%02d0%02d', (localtime)[2, 1, 0];
for my $mask (8, 4, 2, 1) {
    print "   ";
    for my $d (split //, $time) {
        print $d & $mask ? '## ' : '   ';
    }
    print "\n $mask ";
    for my $d (split //, $time) {
        print $d & $mask ? '## ' : '   ';
    }
    print "\n\n";
}
print "   HH HH    MM MM    SS SS\n";
[download]

As you appear to want to run this in a loop, and display the result in a terminal window, you'll likely will have to dig into ANSI codes. You can change foreground and background colors, which may allow you to just print colored spaces. There are also control codes to move the cursor to any place on the screen.

A quick Goolge search brought me to this page, which might just contain enough info to make it do what you want: VT-100 Escape Codes

OK, let's test it.

#!/usr/local/bin/perl -w
my $old = '';
print "\e[2J";
while(1){
    print "\e[1;1H";
    my $time = sprintf '%02d0%02d0%02d', (localtime)[2, 1, 0];
    if($time eq $old) {
        sleep 1;
        redo;
    }
    $old = $time;
    for my $mask (8, 4, 2, 1) {
        print "   ";
        for my $d (split //, $time) {
            print $d & $mask ? "\e[7m  \e[m " : '   ';
        }
        print "\n $mask ";
        for my $d (split //, $time) {
            print $d & $mask ? "\e[7m  \e[m " : '   ';
        }
        print "\n\n";
    }
    print "   HH HH    MM MM    SS SS\n";
    sleep 1;
}
[download]

Update: Fixed bug in fetching time always with 2 digits.

use Term::Cap;

$OSPEED = 9600;
eval {
    require POSIX;
    my $termios = POSIX::Termios->new();
    $termios->getattr;
    $OSPEED = $termios->getospeed;
};

$terminal = Term::Cap->Tgetent({OSPEED=>$OSPEED});
$terminal->Tputs('cl', 1, STDOUT);
[download]

$clear = `clear`;
while (1){
    print $clear;
    $time = localtime();
    print "$time\n";
    sleep 1;
    $l++;
}
[download]

A *real* geek clock would of course be:

perl -e'printf "%b\n", time while sleep 1'
[download]

- Yes, I reinvent wheels.
- Spam: Visit eurotraQ.

For those trying not to go quite so totally geek, a slightly less extreme clock might be something along the lines of:

#!/usr/bin/perl -w

use strict;

$| = 1;

# Set $nice_to_nongeeks true 
#   to use dual-format display 
#   for those not yet fluent in binary.
my $nice_to_nongeeks = 1;

while (1) {
    my @time_components = localtime(time);
    my $datestring      = "The current time is: "
      . join ( ':',
        unpack( "B*", pack( "C", $time_components[2] ) ),
        unpack( "B*", pack( "C", $time_components[1] ) ),
        unpack( "B*", pack( "C", $time_components[0] ) ) );
    if ($nice_to_nongeeks) {
        $datestring .= ' ('
          . join ( ':',
            substr('00' . $time_components[2], -2),
            substr('00' . $time_components[1], -2),
            substr('00' . $time_components[0], -2) )
          . ')';
    }

    # Append to the string its length in backspace 
    #   characters so as to overwrite its previous output.
    # (There may perhaps be some terminals where 
    #   this might not work, however.)
    $datestring .= "\b" x length($datestring);
    print($datestring);
    sleep(1);
}
[download]

(I thought the idea of a binary clock was cool, but didn't like represent-each-digit-as-binary approach, thinking the represent-each-component-as-binary was a little more true to the idea.)

Enjoy.

Update: Modified code to force time components in dual-display mode to 2 digits.

If you don't care about burning machinecycles, you can just put the program in an eternal loop, outputting the things you want at a much faster rate than once a second (just drop the sleep 1): if the present output did not change from the previous output, the screen would seem not to have changed at all, although of course, it was refreshed with the same pattern as before.

CountZero

"If you have four groups working on a compiler, you'll get a 4-pass compiler." - Conway's Law