I've not personally used it, but the module Lingua::EN::NameCase may be useful. It seems to have a series of rules that deal with cases like the following:

Original            Name Case
--------            ---------
KEITH               Keith
LEIGH-WILLIAMS      Leigh-Williams
MCCARTHY            McCarthy
O'CALLAGHAN         O'Callaghan
ST. JOHN            St. John
[download]

Regards,
Dom.

Howdy!

...but feed it "Owen ap Tudor", "Sveinn inn Danska", and "David ben Jesse"...

Of course, that's Lingua::EN::NameCase, not Lingua::welsh, scandihoovian, or jewish::NameCase...

The original question has no general solution, since name capitalization conventions vary from culture to culture.

yours,
Michael

Hi herveus,

++ on the point that there is no general solution to this problem but I thought I would just check out how Lingua::EN::NameCase would deal with your examples...

#perl -w
use strict;
use warnings;
use Lingua::EN::NameCase qw( NameCase nc ) ;

my @proper_names = (
    'Owen ap Tudor', 
    'Sveinn inn Danska',
    'David ben Jesse'
);

my @lowercase_names = map { lc } @proper_names ;

my @result = NameCase( @lowercase_names ) ;

my ($iCount, $bMatch);

for ($iCount = 0; $iCount <= $#result; $iCount++) {
    $bMatch = $proper_names[$iCount] eq $result[$iCount] ? 'Y' : 'N';
    write;
}

exit;

format STDOUT_TOP =
Orignal case                    Output from NameCase            Match
==============================  ==============================  =====
.

format STDOUT =
@<<<<<<<<<<<<<<<<<<<<<<<<<<<<<  @<<<<<<<<<<<<<<<<<<<<<<<<<<<<<  @<<<<
$proper_names[$iCount],         $result[$iCount],             $bMatch
.

__END__
[download]

Surprisingly the output looks like this:

Orignal case                    Output from NameCase            Match
==============================  ==============================  =====
Owen ap Tudor                   Owen ap Tudor                   Y
Sveinn inn Danska               Sveinn Inn Danska               N
David ben Jesse                 David ben Jesse                 Y
[download]

"Sveinn Inn Danska" is not correct but surprisingly for a Lingua::EN module it does deal well with the other cases. Also from the documentation there is a variable that can be set to deal with special cases for Spanish... Perhaps the module itself has evolved to become a misnomer.

Regards,
Dom.

Update: Corrected typo on link.
Update: Corrected typo on incorrect name.

This should do what you want:

  my $upcased = join(" ", map(ucfirst($_), split(/\s+/, $str)));
[download]

Hope this helps, -gjb-

++gjb. Here is a variation which better preserves the original: my $upcased = join '', map { ucfirst } split /(\s+)/, $str; The parens in split's pattern make the seperating string be included in the resulting list. The ucfirst function has no effect on the captured whitespace.

After Compline,
Zaxo

$name =~ s/(?:\s|^)(\w)/uc($1)/eg;
[download]

Faster and easier to read. (Shorter without obfuscation means less for the human to parse.)

------
We are the carpenters and bricklayers of the Information Age.

Don't go borrowing trouble. For programmers, this means Worry only about what you need to implement.

jeffa

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)

Simpler:

   s/\b(\w)/\u$1/g;
[download]

Abigail