Here's a demonstration of how using regular expression pattern matching instead of string split might be more correct, robust and extensible.

#!perl

use strict;
use warnings;

my $valid_vehicle_description_pattern = qr{
    ((?:19|20)\d\d)        # $1 is Year
    \s+
    (                      # $2 is Make
        British\s+Leyland
      | Chev(?:y|rolet)
      | Dodge
      | Ford
      | (?:General\s+Motors|GMC?)
      | Hyundai
      | Kia
      | Nissan
      | Toyota
    )
    \s+
    (\S.*)                 # $3 is Model
}ix;

while (my $vehicle = <DATA>) {
    chomp $vehicle;

    if ($vehicle =~ $valid_vehicle_description_pattern) {
        my ($year, $make, $model) = ($1, $2, $3);

        print "Year: $year\tMake: $make\tModel: $model\n";
    }
    else {
        warn "Invalid vehicle description: $vehicle\n";
    }
}

__DATA__
1970 British Leyland Triumph Spitfire
2011 CHEVROLET CAMARO
2011 Chevy Camaro
2011 Dodge Ram Crew Cab Short Bed
2011 Ford F150 Platinum
2011 Ford Flex
2011 Ford Transit
2011 GMC Cargo Van Extended
2011 Hyundai Genesis Coupe
2011 Kia Sol
2011 Nissan Cube
2011 Toyota Prius
2015 Apple iCar

[download]

In reply to Re^3: Parse file, split by Jim
in thread Parse file, split by mewoq

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.