One classic way is to just keep track of the most recent contender, and the one you're still holding at the end is the winner:

use File::Basename;

my $found;
while( <DATA> ) {
  chomp;
  my $bn = basename($_);
  next unless $bn =~ m/^\d+$/;
  $found = $bn;
}
print $found;

__DATA__
/path/to/one/library
/path/to/another
/path/to/another/01
/path/to/another/s
/path/to/another/02
/path/to/another/w1
/path/to/another/03
/path/to/another/1e
/path/to/another/2014
[download]

If the file is large enough that you don't want to spend time reading the whole thing, you could use a File::ReadBackwards solution:

# Untested...
use File::Basename;
use File::ReadBackwards;

tie *FH, 'ReadBackwards', 'filename' or die $!;

my $found;
while( <FH> ) {
  chomp;
  next unless basename($_) =~ m/^(\d+)$/;
  $found = $1;
  last;
}

die "No matches found.\n" unless defined $found;
print $found;
[download]

Or if the file's not huge, you could just slurp it into an array and reverse the array:

use File::Basename;

my @files = reverse <DATA>;
my $found;
foreach ( @files ) {
  chomp;
  next unless basename($_) =~ m/^(\d+)$/;
  $found = $1;
  last;
}

die "No matches found.\n" unless defined $found;
print $found;

__DATA__
/path/to/one/library
/path/to/another
/path/to/another/01
/path/to/another/s
/path/to/another/02
/path/to/another/w1
/path/to/another/03
/path/to/another/1e
/path/to/another/2014
[download]

Of course if you're going to slurp it, you probably don't really need the @files variable:

foreach ( reverse <DATA> ) {
  ...
[download]

This still slurps, and people generally advise against iterating over a filehandle within a foreach loop, because the foreach loop does implicitly slurp the file. But in this case, that's the behavior we actually want.

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.