Here's some sample code, using Perl's flock function, that I've used for many years on both Unix and Windows, to ensure only one copy of a script is running at a time (update: run on local file systems only, not NFS).

use strict;
use warnings;
use Fcntl ':flock';    # import LOCK_* constants

warn "program starts\n";

my $somelockfile = 'choosealockfilename';    # adjust according to you
+r needs
open(my $fhlock, '>', $somelockfile) or die "Error: open '$somelockfil
+e': $!";

warn "before flock: filename='$somelockfile'\n";
 
# Note: process will block at this point until the lock is acquired.
flock($fhlock, LOCK_EX) or die "Error: flock '$somelockfile': $!";
 
# Lock is now held until $fhlock is closed.
# Note that even if this program crashes or is killed, $fhlock will
# be closed by the OS and the lock released.
# ...

warn "Got lock, sleeping for 10 secs...\n";
sleep 10;
warn "woke up\n";

# Release the lock simply by closing the file handle.
close $fhlock or die "Error: close '$somelockfile': $!";

warn "lock released: sleeping for 5 secs...\n";
sleep 5;

warn "program ends\n";
[download]

You can easily test its behaviour by running the little test program above in two different terminal sessions (and either waiting for the sleep to end or manually killing one of the processes).

Apart from providing portable locking across Unix and Windows, flock has long been a favourite of Perl poets, as beautifully shown by pjf in this immortal line:

join flock($other,@chickens) if split /from others/;
[download]

from his classic poem my @chickens (by the way, pjf is one of the few monks I've met in real life; in addition to running chickens in his backyard, he has a keen interest in picking and eating unusual and delicious wild plants you won't find in any supermarket ... not for the faint-hearted, you need a keen eye and expert knowledge to avoid being poisoned).

References Added Later

• File Locking Tricks and Traps by MJD (mentioned by davido here)
• Ensuring only one copy of a perl script is running at a time by me (2006)
• Highlander - allow only one invocation at a time of an expensive CGI script by merlyn (2000)

• File lock demo by LanX (2021)
• singleton lock not reliable by pidloop (2021)

• Mechanism for ensuring only one instance of a Perl script can only run? by redapplesonly (Dec 2022)
• Ensure Only One Instance of Your Script is Running... with 'ps -ef' ? by redapplesonly - same question one week later! (Dec 2022)

• Re: what is the meaning of $| in perl? (Buffering/autoflush/Unicode/UTF-8 References) by me (2014)
• Storable - File empties itself? by feumw (2023) (this node is mentioned in this reply)

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.