##############server###########################
#!/usr/bin/perl
use strict;
use warnings;
use IO::Socket;
use Tk;

$|=1;
$SIG{PIPE} = 'IGNORE';

my $listen = IO::Socket::INET->new(
    Proto       => 'tcp',
    LocalPort   => 7070,
    Listen      => 3,
    Reuse       => 1,
) or die "Can't create listen socket : $!\n";

my $mw = MainWindow->new();
$mw->geometry('+20+20');

my $text = $mw->Scrolled('Text',
                  -background =>'black',
                  -foreground => 'yellow',
                 )->pack();

my $subframe = $mw->Frame()->pack();

$subframe->Button(-text => 'Clear',
         -command => sub {
                      $text->delete('1.0','end');
                   })->pack(-side=>'left');

$subframe->Button(-text => 'Save Log',
         -command => sub {   })->pack(-side=>'left');

$subframe->Button(-text => 'Exit',
         -command => sub { exit  })->pack(-side=>'right');


$mw->fileevent($listen, 'readable', sub { new_connection($listen) });

Tk::MainLoop;

sub new_connection {
    my ($listen) = @_;
    my $client = $listen->accept() or warn "Can't accept connection";
    $client->autoflush(1);
    $mw->fileevent($client, 'readable', sub { handle_connection($clien
+t) });
    $client->print("Connected\n");
    $text->insert('end', "Connected\t");
    $text->see('end');
}
sub handle_connection {
    my ($client) = @_;
    my $message = <$client>;
    if (defined $message and $message !~ /^quit/) {
     $message =~ s/[\r\n]+$//;
     $client->print("Got message [$message]\n"); #echo back if wanted 
     $text->insert('end', "Got message [$message]\t");
     $text->see('end');
    }
    else {
       $text->insert('end', "Connection Closed\n");
       $text->see('end');
       $client->close();
    }
}
__END__
<code>
<code>
############clients#########################
#!/usr/bin/perl
use warnings;
use strict;
use IO::Socket;

$|++;

my $name = 'foo';

while(1){

my $sock = new IO::Socket::INET (
      PeerAddr => 'localhost',
      PeerPort => '7070',
      Proto => 'tcp',
         );
  die "Could not create socket: $!\n" unless $sock;

$sock->autoflush(1);

 my $con_msg = <$sock>;
   print $con_msg,"\n";

  print $sock $name.time,"\n";

  my $msg = <$sock>;
   print $msg;
   $sock->close();
   sleep(5);
}

exit 0;
[download]