#!/usr/bin/perl
use strict;
use warnings;

{
    my %seen;
    my %tree = (
        A => ['B', 'C'], B => ['D', 'E'], C => ['F', 'G'],
        E => ['H', 'I'], G => ['J', 'K'], H => ['L', 'M', 'N'],
        I => ['O', 'P'], K => ['Q'],   
    );

    sub get_root { 'A' }

    sub visited {
        my ($node, $val) = @_;
        return $seen{$node} = $val if defined $val;
        return $seen{$node};
    }

    sub gen_child_iter {
        my ($node) = @_;
        return if ! $tree{$node};
        my ($pos, $max) = (-1, $#{$tree{$node}});
        return sub {
            ++$pos;
            return if $pos > $max;
            return $tree{$node}[$pos];
        };
    }
}

sub gen_tree_iter {
    my @nodes = get_root();
    return sub {
        {
            my $node = shift @nodes;
            return undef if ! defined $node;
            if (ref $node eq 'CODE') {
                my $child = $node->();
                redo if ! defined $child;
                unshift @nodes, $node;
                $node = $child;
            }
            redo if visited($node);
            visited($node => 1);
            my $child_iter = gen_child_iter($node);            
            unshift @nodes, $child_iter if defined $child_iter;
            return $node;
        }
    };
}
my $iter = gen_tree_iter();

while (my $node = $iter->()) {
    print "Visiting $node\n";
}
[download]