Not addressing your threads problem but there are a couple of possible issues with your code.

• In your first while loop the temporary array @copy is unnecessary, just use the splice inside an anonymous array constructor ([ ... ]). The while could also become a statement modifier if you like (see Statement Modifiers).
• Choosing the same names for arrays and scalars can be confusing. Perhaps @xyz_chunks and $xyz_chunk would have been better. Some recommend that you name scalars that contain references to something else in an easily identified way, e.g. $raWhatever for an array reference, $rhThose for a hash reference etc. (I tend to use camel-case, others prefer underscores in their identifiers.)
• There are a couple of points about your second while. It looks like you only use @working inside the loop so it's declaration should be moved inside.
• Secondly, the while might be better as a foreach so you iterate over each element in turn aliasing it to some scalar (or $_ by default).
• I second toolic's advice regarding Data::Dumper. It looks like you might be already using strictures since you have declared some of the variables in your code but the advice bears repeating. Always put use strict; and use warnings; at the top of your scripts.

Here is a short script putting the points mentioned above into practice.

use strict;
use warnings;

use Data::Dumper;

my @xyz = map { sprintf q{%02d}, $_ } 1 .. 23;
my @xyzChunks = ();

print Data::Dumper->Dumpxs(
   [ \ @xyz, \ @xyzChunks ],
   [ qw{ *xyz *xyzChunks } ]
   );
print q{=} x 50, qq{\n};

push @xyzChunks, [ splice @xyz, 0, 10 ] while @xyz;

print Data::Dumper->Dumpxs(
   [ \ @xyz, \ @xyzChunks ],
   [ qw{ *xyz *xyzChunks } ]
   );
print q{=} x 50, qq{\n};

foreach my $raXyzChunk ( @xyzChunks )
{
    print qq{Debug: @$raXyzChunk\n};
}
[download]

The output.

@xyz = (
         '01',
         '02',
         '03',
         '04',
         '05',
         '06',
         '07',
         '08',
         '09',
         '10',
         '11',
         '12',
         '13',
         '14',
         '15',
         '16',
         '17',
         '18',
         '19',
         '20',
         '21',
         '22',
         '23'
       );
@xyzChunks = ();
==================================================
@xyz = ();
@xyzChunks = (
               [
                 '01',
                 '02',
                 '03',
                 '04',
                 '05',
                 '06',
                 '07',
                 '08',
                 '09',
                 '10'
               ],
               [
                 '11',
                 '12',
                 '13',
                 '14',
                 '15',
                 '16',
                 '17',
                 '18',
                 '19',
                 '20'
               ],
               [
                 '21',
                 '22',
                 '23'
               ]
             );
==================================================
Debug: 01 02 03 04 05 06 07 08 09 10
Debug: 11 12 13 14 15 16 17 18 19 20
Debug: 21 22 23
[download]

I hope these points are of interest.

Cheers,

JohnGG