Here's what I have:

Nice fragment :) here is a complete program 

#!/usr/bin/perl --

use strict;
use warnings;

use HTML::TreeBuilder;

Main(@ARGV);
exit(0);

sub Main {
    my $html = '<html><body>
<img src="0" alt="0">
<img src="1" alt="1">
<img src="2" alt="2">
<img src="3" alt="">
<img src="4">
<img src="5">
</body></html>';

    my $tree = HTML::TreeBuilder->new();
    $tree->parse($html);

    local $\ = $/;
    print $_->as_HTML
      for $tree->look_down( qw' _tag img ',
        sub { not defined $_[0]->attr('alt') } );

    print '---';

    print $_->as_HTML
      for $tree->look_down( qw' _tag img ',
        sub { not length $_[0]->attr('alt') } );

    print '---';

    $_->attr( alt => MAlt($_) )
      for $tree->look_down( qw' _tag img ',
        sub { not length $_[0]->attr('alt') } );
    print $_->as_HTML for $tree->look_down(qw' _tag img ');
} ## end sub Main

sub MAlt { '!' . $_[0]->attr('src') }

__END__
<img src="4" />
<img src="5" />
---
<img alt="" src="3" />
<img src="4" />
<img src="5" />
---
<img alt="0" src="0" />
<img alt="1" src="1" />
<img alt="2" src="2" />
<img alt="!3" src="3" />
<img alt="!4" src="4" />
<img alt="!5" src="5" />

[download]
Alternatively, try HTML::TreeBuilder::XPath 
#!/usr/bin/perl --

use strict;
use warnings;

use HTML::TreeBuilder::XPath;

Main(@ARGV);
exit(0);

sub Main {
    my $html = '<html><body>
<img src="0" alt="0">
<img src="1" alt="1">
<img src="2" alt="2">
<img src="3" alt="">
<img src="4">
<img src="5">
</body></html>';

    my $tree = HTML::TreeBuilder::XPath->new();
    $tree->parse($html);

    local $\ = $/;
    print $_->as_HTML for $tree->findnodes('//img[not(@alt)]');

    print '---';

    print $_->as_HTML for $tree->findnodes('//img[not(string-length(@a
+lt))]');

    print '---';

    $_->attr( alt => MAlt($_) )
      for $tree->findnodes('//img[not(string-length(@alt))]');
    print $_->as_HTML for $tree->findnodes('//img');
} ## end sub Main

sub MAlt { '!' . $_[0]->attr('src') }

__END__

[download]

In reply to Re: Trying to Insert Alt Tags Programmatically by Anonymous Monk
in thread Trying to Insert Alt Tags Programmatically by socrtwo

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.