Regular expressions are very fragile for HTML parsing. Here's a parser (XML::LibXML) based example– 

use strictures;
use XML::LibXML;
use open qw(:std :utf8);
use YAML;

my $dom = XML::LibXML->load_html( string => do { local $/; <DATA> },
                                  keep_blanks => 0 );

my @advisories;
# Only select <c><p></c>s that have a PDF link inside.
for my $p ( map { $_->parentNode } $dom->findnodes(q{//p//a[contains(@
+href,'.pdf')]}) )
{
    my %tmp;
    for my $kid ( $p->childNodes )
    {
        if ( $kid->nodeName eq "a" )
        {
            $tmp{pdf} = { title => $kid->textContent,
                          href => $kid->getAttribute("href")
            };
        }
        elsif ( not $tmp{pdf} )
        {
            # You'd have to do some shuffling to handle <br/>->\n here
+.
            $tmp{heading} .= $kid->textContent;
        }
        else
        {
            ( $tmp{date} = $kid->textContent ) =~ s/[)(\n\r]//g;
        }
    }
    s/[\s,]+\Z// for $tmp{heading}, $tmp{date};

    push @advisories, \%tmp;
}

print YAML::Dump(\@advisories);

exit 0;

__DATA__
# YOUR HTML FRAGMENT HERE

[download]

Snippet of output

---
- date: 'March 21, 2011'
  heading: |-
    RealFlex TechnologiesMultiple Vulnerabilities in
    RealFlex RealWin
  pdf:
    href: /control_systems/pdf/ICS-ALERT-11-080-04.pdf
    title: ICS-ALERT-11-080-04
- date: 'April 20, 2011'
  heading: RealFlex RealWin Multiple Vulnerabilities
  pdf:
    href: /control_systems/pdf/ICSA-11-110-01.pdf
    title: ICSA-11-110-01
...

[download]

I do understand that regular expressions seem more accessible at first and can solve many specific/one-off problems but putting in the time to get up the learning curve of any of the good HTML/XML parsers will repay greatly over time.

In reply to Re: Parsing and searching HTML code by Your Mother
in thread Parsing and searching HTML code by jayto

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.