my $rex = qr/Fifth/;
my @last_four;

while(<DATA>) {
    push @last_four, $_;
    shift @last_four if @last_four > 4;

    print @last_four if $_ =~ $rex;
}

__DATA__
First
Second
Third
Forth
Fifth
Sixth
[download]

The simplest way is to redefine what is considered to be a line. That is done by setting $/ to the delimiter text.

my @errors;
{
    local $/ = "=================================\n";
    open my $fh, '<', '/path/to/file.txt' or die $!;
    while (<$fh>) {
        chomp;
        push @errors, $_ if /D : Error Occurred/;
    }
    close $fh or die $!;
}
[download]

This assumes that you'll never see D: without first seeing A: and B: in the same record.

my ( $adata, $bdata );
while ( <DATA> ) {
    chomp;
    m/^A:\s*(\S)$/ and $adata = $1;
    m/^B:\s*(\S)$/ and $bdata = $1;
    m/^D:/ and do { print "A: $adata, B: $bdata\n"; last; };
}
[download]

tie @l, "Tie::File", $file or die $!;
for my $i (0 .. $#l) {
    if ($l[$i] =~ /Error Occurred/) {
        while($i > 0) {
            $i--;
            if ($l[$i] =~ /(A|B):\d+/) {
                print $l[$i];
                exit; # or last
            } elsif ($l[$i] =~ /^====/) {
                exit; # or last
            }
        }
     }
}
[download]

Another alternative could use a combination of a normal filehandle to go forward in the file, and File::ReadBackwards to go backward in the same file.

my @last_lines;
while (<>) {
   if ($_ eq "D : Error Occurred\n") {
      print @last_lines,$_;
      last;
   }
   push @last_lines,$_; 
   shift @last_lines if @last_lines > 4;
}
[download]

If you really only need the first 2 lines after the last "====" line, then maybe this is a good start:

my @last_lines;
while (<>) {
   if ($_ eq "D : Error Occurred\n") {
      print @last_lines,$_;
      last;
   }
   if (/===/) {
      @last_lines =();
   }
   elsif (@last_lines < 2) {
      push @last_lines,$_;
   }
}
[download]