I would do it recursively:

use warnings;

@denoms = qw(2 5 10 20 50 100);

sub change {
  my ($unchanged, $nothing_smaller_than) = (@_,0);
  my @results = ();
  for my $trybill (@denoms) {
    next if ($trybill < $nothing_smaller_than);
    if ($trybill < $unchanged) {
      my $remaining = $unchanged - $trybill;
      push @results, map {[$trybill, @$_]} change($remaining, $trybill
+);
    }
    elsif ($trybill == $unchanged) {
      push @results, [$trybill];
    }
    else { last }
  }
  return @results;
}

use Data::Dumper;
print Dumper change(100);
[download]

Try each denomination against what is to be changed. If the bill being tried ($trybill) is less than the amount to be changed ($unchanged), then make a result set out of $trybill mapped to each combination returned by change($unchanged-$trybill).

The $nothing_smaller_than parameter ensures that the output doesn't result in multiple permutations of the same combination of bills: only the canonical order of smallest bill to largest bill will be returned.