perldoc -q "expand variables" says:

       How can I expand variables in text strings?

       Let's assume that you have a string like:

           $text = 'this has a $foo in it and a $bar';

       If those were both global variables, then this would suffice:

           $text =~ s/\$(\w+)/${$1}/g;  # no /e needed

       But since they are probably lexicals, or at least, they could b
+e, you'd
       have to do this:

           $text =~ s/(\$\w+)/$1/eeg;
           die if $@;                  # needed /ee, not /e

       It's probably better in the general case to treat those variabl
+es as
       entries in some special hash.  For example:

           %user_defs = (
               foo  => 23,
               bar  => 19,
           );
           $text =~ s/\$(\w+)/$user_defs{$1}/g;
[download]

Use one of the various templating modules from CPAN:

• Text::Template

  use strict;
  use warnings;
  use Text::Template;
  
  my $template = Text::Template->new(
      TYPE   => 'STRING',
      SOURCE => 'fred has {$color} eyes'
  );
  
  our $color = 'blue';
  print $template->fill_in;
  [download]

• HTML::Template

  use strict;
  use warnings;
  use HTML::Template;
  
  my $data = 'fred has <tmpl_var color> eyes';
  
  my $template = HTML::Template->new(
      scalarref => \$data,
  );
  
  $template->param(
      color => 'brown',
  );
  
  print $template->output;
  [download]

• Template

  use strict;
  use warnings;
  use Template;
  
  my $data = 'fred has [% color %] eyes';
  my $vars = {
      color => 'blue',
  };
  
  my $tt = Template->new;
  $tt->process(\$data, $vars) || die $tt->error;
  [download]

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)

$raw = '$parsed = "fred has $color eyes";';

eval $raw;

print $parsed;
[download]

While this will work fine, it's probably not a good idea. Especially if you don't know ahead of time what's going to be in $raw, any malicious code that gets put there will be evaled by your program. Further, string eval is quite slow from what I hear. Instead, I would highly reccomend using the hash lookup method provided by cmeyer above.

Unless you can guarantee that $color is always a string without meta characters, this is safer:

$raw = '$parsed = "fred has \Q$color\E eyes";';
eval $raw;
print $parsed;
[download]

"What should it profit a man, if he should win a flame war, yet lose his cool?"