$line = <FILENAME>;
    while ($line ne "")
        {
        print "$line";
        $line = <FILENAME>;
        }
[download]

    while (<FILENAME>)
        {
        print ;
        }
[download]

One way to tweak the above to get your desired output is as follows:

    while (<FILENAME>)
        {
        last if /<!-- Begin -->/;
        }
    while (<FILENAME>)
        {
        last if /<!-- End -->/;
        print ;
        }
[download]

I would think that if there's text after <!-- BEGIN --> but on the same line, it would not be printed, as well as the text before <!-- End -->

--------------------------------
An idea is not responsible for the people who believe in it...

OK, this one worked! Thanks, jdporter!

_____________________________________________________
mojobozo
word (wûrd)
interj. Slang. Used to express approval or an affirmative response to
something. Sometimes used with up. Source

while (<>)
{
  if (/<!-- Begin -->/ .. /<!-- End -->/) 
  {
    print;
  }
}
[download]

Or, more concisely:

(/<!-- Begin -->/ .. /<!-- End -->/) && print while (<>);
[download]

See Range Operators in perlref(1) for more information.

You will get all manner of horrible things happen to your current code if the page that you're editing happens to contain the string "</textarea>" in it anywhere.

You should escape the HTML that you are printing inside the text box to get around this. At a minimum, replacing all instances of "<" with "&lt;" should do the trick. There are modules such as HTML::Sanitizer which try to do this in a more sophisticated way.

my $file = '/path/to/file.txt';
open(IN,"<$file") || die $!;
read IN, my $html, -s $file;
close(IN);
$html =~ s/<!-- Begin -->(.*?)<!-- End -->/$1/s;
[download]

my $flag = 0;
while (<FILE>) {
    $flag = 1 if (/<!-- Begin -->/);
    $flag = 0 if (/<!-- End -->/);

    process_line($_) if ($flag);
}
[download]

I notice you have a different method for reading an entire file into memory then I am used to seeing. I was wondering if there is any reason you are aware of that makes your way better or worse than the way I use (or if they are just different (TIMTOWTDI)). If there is, I'd love to hear about it.

read IN, my $html, -s $file;     # your code
my $file = do{ local $/; <IN> }; # The way I usually use.
[download]

Other monks... can anybody tell me if there is an advantage in one way or the other?

Update The secode line of cone above is the way I am used to seeing... I forgot to complete the comment. My question regards the difference between using $/ as opposed to using read to slurp in an entire file.

---

They say that time changes things, but you actually have to change them yourself.

—Andy Warhol

What is the way you're used to seeing? Maybe I am the one in need of enlightenment and your way is superior.

To answer your question, there is no reason why I do it that way except that's the way I learned how to do it. Maybe there was a good reason to do it like that back then which has now been made moot by advances in Perl - I don't know.

IMO, the difference will be what kind of buffered I/O gets performed. Fuller explanation: Re: Speed reading (files)

One world, one people

#Sample data, multiline
$line = "<!-- Begin -->Line one\nLine two\nthree\nfour<!-- End -->";

#process them
$line =~ s/<!-- Begin -->(.*)<!-- End -->/$1/s;
print $line;
[download]

I tried to do the same while reading the file line-by-line... The code was so ugly that I simply recommend to read in the whole file at once and do a multiline regexp above...

HTH

Using [id://jdporter]'s code:

    while (<FILENAME>)
        {
        last if /<!-- Begin -->/;
        }
    while (<FILENAME>)
        {
        last if /<!-- End -->/;
        s/^\s*//; #<- new line here
        print ;
        }
[download]

I have comments in the file and want to grab the stuff between them.

#!/bin/perl5

use strict;
use warnings;
use HTML::TokeParser;

my $file = 'index.html';
my $tp = HTML::TokeParser->new($file)
  or die "Couldn't parse $file: $!";

my ($start, $html);
while (my $tag = $tp->get_token) {

  if ( 
    $tag->[0] eq 'C' and 
    $tag->[1] eq '<!-- article start -->'
  )
  { 
   $start++;
   next;
  }

  next unless $start;

  if (
    $tag->[0] eq 'C' and
    $tag->[1] eq '<!-- article end -->'
  )
  {
    last;
  }

  $html .= $tag->[4] if $tag->[0] eq 'S';
  $html .= $tag->[1] if $tag->[0] eq 'T' or $tag->[0] eq 'C';
  $html .= $tag->[2] if $tag->[0] eq 'E';

}

print "$html\n";

# ["S",  $tag, $attr, $attrseq, $text]
# ["E",  $tag, $text]
# ["T",  $text, $is_data]
# ["C",  $text]
# ["D",  $text]
# ["PI", $token0, $text]
[download]