Finding the position could be done as follows:

my ($pos) = grep { ... } 0..$#array;
[download]

where ... checks $array[$_] for the condition.

Once you find the position,

push(@array, splice(@array, $pos, 1))
[download]

will do the trick nicely.

Actually a simple splice/push will not change the position of an element in an array, it will create a new element that comtains a copy of the value from the old of element.

my @array = ( 'foo', 'bar', 'baz' );
my ($pos) = grep { $array[$_] eq 'bar' } 0..$#array;
my $ref_to_element = \$array[$pos];
push (@array, splice(@array, $pos, 1));
print "@array\n"; # Prints 'foo baz bar'
$$ref_to_element = 'zap';
print "@array\n"; # Still prints 'foo baz bar'
[download]

Had $array[1] been moved to the end of the array then $$ref_to_element would point to $array[2] after the move.

Admittedly, this is usually not an issue.

On the rare occasions when you really want to move elements of an array use Array::Splice. In the above example you would use push_aliases() in place of the built-in push().

my $pos;
for (0..$#array) {
    $pos=$_ and last
      if $array[$_] eq $wanted;
}
@array[$pos,-1]=@array[-1,$pos];
[download]

Update: it was a wonderfully neat solution (which is the reason why I posted it!) to another problem!!

Not just as neat:

my $pos;
for (0..$#array) {
    $pos=$_ and last
      if $array[$_] eq $wanted;
}
@array=@array[0..$pos-1, $pos+1..$#array, $pos];
[download]

And what if no one of them matched? (Left as an exercise to the reader ;-)

But then if you are sure in advance that one and only one element will match, here's a neat concise solution:

@array=((grep $_ ne $wanted, @array), $wanted);
[download]

Here is one type of approach that you can use.

for( $i = 0; $i < @array; $i++){
   if( $array[$i] == $look ) {
      @out = (@array[0..($i-1)], @array[($i+1)..scalar(@array)], $arra
+y[$i]);
      last;
   }
}
[download]