It's not clear what you want, but the following may give you some interesting ideas:

use strict;
use warnings;

my @ahoa=(    
    {1=> ['A'=>1.1, 'B'=>10.1, 'C'=>100.1],
    2=> ['A'=>2.1, 'B'=>20.1, 'C'=>200.1],
    3=> ['A'=>3.1, 'B'=>30.1, 'C'=>300.1]},
               
    {4=> ['A'=>4.1, 'B'=>40.1, 'C'=>400.1],
    5=> ['A'=>5.1, 'B'=>50.1, 'C'=>500.1],
    6=> ['A'=>6.1, 'B'=>60.1, 'C'=>600.1]},
    
    {7=> ['A'=>7.1, 'B'=>70.1, 'C'=>700.1],
    8=> ['A'=>8.1, 'B'=>80.1, 'C'=>800.1],
    9=> ['A'=>9.1, 'B'=>90.1, 'C'=>900.1]},
);


print dumpRef(\@ahoa);

sub dumpRef {
    my $ref = shift;
    
    if ('ARRAY' eq ref $ref) {
        my $str = '';
        
        $str .= dumpRef ($_) for @$ref;
        return "$str\n";
    } elsif ('HASH' eq ref $ref) {
        my $str = '';
        
        $str .= " $_ => " . dumpRef ($ref->{$_}) for sort keys %$ref;
        return "$str\n";
    } elsif (length ref $ref) {
        return 'Panic - got a ' . (ref $ref) . ' and can\'t deal with 
+it.';
    } else {
        return " $ref";
    }
}
[download]

Prints:

 1 =>  A 1.1 B 10.1 C 100.1
 2 =>  A 2.1 B 20.1 C 200.1
 3 =>  A 3.1 B 30.1 C 300.1

 4 =>  A 4.1 B 40.1 C 400.1
 5 =>  A 5.1 B 50.1 C 500.1
 6 =>  A 6.1 B 60.1 C 600.1

 7 =>  A 7.1 B 70.1 C 700.1
 8 =>  A 8.1 B 80.1 C 800.1
 9 =>  A 9.1 B 90.1 C 900.1
[download]

I guess this is an array of hash arrays, right?

It is an array of hashrefs. Each value in the hashrefs is an arrayref. Each arrayref uses (for some reason) fat commas (=>) and has data that suggests it should really be a hashref.

I have problems with printing this thing could you help me please?

That probably won't give you what you want, but your question wasn't very specific (and you failed to provide the code your wrote to try to achieve your goal). You should probably have a read of the first three items listed under "Tutorials" in perldoc perl.

for my $h(@ahoa) {
   for (keys(%$h)){
       print "$_ => ";
       print "@{$h->{$_}}\n";
   }
   print "\n";
}
[download]

for my $h (@ahoa) {
    my %deref = %$h;
    for my $k (keys(%deref)) {
        print "$k=> ";
        my @deref = @{$deref{$k}};
        print "@deref\n";
    }
    print "\n";
}
[download]

I have done it in the following way:

#!/usr/bin/perl -w

use strict;

my @ahoa=(     

{1=> {'A'=>1.1, 'B'=>10.1, 'C'=>100.1}, 
2=> {'A'=>2.1, 'B'=>20.1, 'C'=>200.1}, 
3=> {'A'=>3.1, 'B'=>30.1, 'C'=>300.1} }, 
            
{4=> {'A'=>4.1, 'B'=>40.1, 'C'=>400.1}, 
5=> {'A'=>5.1, 'B'=>50.1, 'C'=>500.1}, 
6=> {'A'=>6.1, 'B'=>60.1, 'C'=>600.1} }, 
            
{7=> {'A'=>7.1, 'B'=>70.1, 'C'=>700.1}, 
8=> {'A'=>8.1, 'B'=>80.1, 'C'=>800.1},
9=> {'A'=>9.1, 'B'=>90.1, 'C'=>900.1} }, );
            
for(my $i=0; $i<(scalar(@ahoa)); $i++)
{    
    print "i: $i\n";
    print "\n";
                
    for my $alphakey (sort {$a <=> $b} keys %{$ahoa[$i]})
    {    
        print "\t AK $alphakey\n";
                    
        for my $betakey (sort {$a cmp $b} keys %{$ahoa[$i]{$alphakey}}
+)
        {print "\t\t $betakey => $ahoa[$i]{$alphakey}{$betakey}\n";}

    }
    print "\n";

}
[download]

thank you all for responding.

Also remember to change the name from "@ahoa" to something that doesn't conflict with the structure of the thing, since it's now an Array of Hashes of Hashes, or a AoHoH for short.

use strict;
use Data::Dumper;

my @ahoa=( ... );

print Dumper \@ahoa;
[download]

Alternately consider using YAML (or YAML::Syck).

use YAML;

my @aohoh = @{ YAML::Load( <<EOT ) };
--- #YAML:1.0
- 1: { A: 1.1, B: 10.1, C: 100.1 }
  2: { A: 2.1, B: 20.1, C: 200.1 }
  3: { A: 3.1, B: 30.1, C: 300.1 }
- 4: { A: 4.1, B: 40.1, C: 400.1 }
  5: { A: 5.1, B: 50.1, C: 500.1 }
  6: { A: 6.1, B: 60.1, C: 600.1 }
- 7: { A: 7.1, B: 70.1, C: 700.1 }
  8: { A: 8.1, B: 80.1, C: 800.1 }
  9: { A: 9.1, B: 90.1, C: 900.1 }
EOT

print YAML::Dump( \@aohoh ), "\n";
[download]

Update: Added use line; I was using perl -MYAML testing but the snippet won't run as is without it.