You can iterate over a given string using the /g (global) quantifier, as well as regex captures:

use strict;
use warnings;

my $string = "ASBSDEC 34 GADVVEEVEETTE 56 IOEOREAK GKJEOG EFEAF 1090 D
+AFFEE 376";

my $max;  # This is undefined until set
while ($string =~ /(\d+)/g) {
    if (!defined($max) or $max < $1) {
        $max = $1;
    }
}

print "Max value is $max\n";
[download]

Or you could make it into a subroutine (eg. max_val) like so:

use strict;
use warnings;

my $string = "ASBSDEC 34 GADVVEEVEETTE 56 IOEOREAK GKJEOG EFEAF 1090 D
+AFFEE 376";
my $max = max_val($string);
print "Max value is $max\n";


sub max_val {
    my $str = shift;
    my $max;
    while ($string =~ /(\d+)/g) {
        if (!defined($max) or $max < $1) {
            $max = $1;
        }
    }
    return $max;        # This will be undefined if no integer found
}
[download]

And, of course, you can read more about regular expressions with perlretut and perlre.

Simple is usually fastest in perl.

#! perl -slw
use strict;
use List::Util qw[ max ];

my %maxs;
$maxs{ $. } = max m[(\d+)]g while <DATA>;

print "line: $_ max: $maxs{ $_ }" for sort keys %maxs;

__DATA__
ASBSDEC 34 GADVVEEVEETTE 56 IOEOREAK GKJEOG EFEAF 1090 DAFFEE 376
ASB C 134 PPKOREAK EFEAF 290
A 100 B 1000 C 2000 D 3000 E 4000  F 5000 G 6000 H 7000 I 8000 J 9000 
+K 10000 L 100000 M 200000 N 2
[download]

Output:

c:\test>junk4
line: 1 max: 1090
line: 2 max: 290
line: 3 max: 200000
[download]

Update: Using an array for output presentation, instead of a hash (as implied by ysth++ below):

#! perl -slw
use strict;
use List::Util qw[ max ];

my @maxs;
$maxs[ $. ] = max m[(\d+)]g while <DATA>;

print "line: $_ max: $maxs[ $_ ]" for 1 .. $#maxs;

__DATA__
ASBSDEC 34 GADVVEEVEETTE 56 IOEOREAK GKJEOG EFEAF 1090 DAFFEE 376
ASB C 134 PPKOREAK EFEAF 290
A 100 B 1000 C 2000 D 3000 E 4000  F 5000 G 6000 H 7000 I 8000 J 9000 
+K 10000 L 100000 M 200000 N 2
[download]

A hash?!

Good point. Originally I had it using the text of the line as the key, but then I thought why not use the line number and made the change.

---

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

"Science is about questioning the status quo. Questioning authority".

In the absence of evidence, opinion is indistinguishable from prejudice.

"Too many [] have been sedated by an oppressive environment of political correctness and risk aversion."

Since There's always MTOWTDI (and I'm experimenting with look-ahead assertions):

#!/perl/bin/perl -w
use strict;
use Data::Dumper;
use List::Util qw/ max /;

my $s = "ASBSDEC 34 GADVVEEVEETTE 56 IOEOREAK GKJEOG EFEAF 1090 DAFFEE
+ 376";

# use a look-ahead assertion to split string into array of strings and
+ numbers
# the corresponding string occupies the index immediately preceding th
+e number
my @arr = split /(\D+)(?=\d+)/, $s;

# grep only for the numbers in the list, selecting the largest one 
print max(grep { /^\d+$/ } @arr), "\n";

__OUTPUT__
1090
[download]

Update: Corrected typo diligently found by liverpole++

Just a question: What is the lookahead needed for?
It seems to mee that

my @arr = split /(\D+)/, $s;
[download]

works as well.
Max

Whenever split() will do, I avoid regex. ++

---

Open source softwares? Share and enjoy. Make profit from them if you can. Yet, share and enjoy!

If you really want to do it with a regex you can:

use strict;
use warnings;
use noname1;

my $str = 'ASBSDEC 34 GADVVEEVEETTE 56 IOEOREAK GKJEOG EFEAF 1090 DAFF
+EE 376';
my $result;
my $biggest = 0;

1 while ($str =~ /(\w+)\s+(\d+)(?{if($2 > $biggest) {$result=[$1, $2];
+ $biggest=$2}})/gx);

print "$result->[0] $result->[1]";
[download]

Prints:

EFEAF 1090
[download]

BTW, to be a bit more complex, is there any way I can get the text before each integer using $'?

Here's an attempt at the last part of your question..

This solution uses split. By putting brackets around the regex, we can get it to return pairs of values - the integers and preceeding text.

#!/usr/bin/perl
use warnings; use strict;

use List::Util;

sub get_text_and_ints {

  my @pairs = split(/([+-]?\d+)/);
  my @text = ();
  my @integers = ();

  while (@pairs) {
    push (@text, shift (@pairs));
    push (@integers, shift (@pairs))
      if (@pairs);
  }

  return (\@text, \@integers);
}
#
# Testing
#
foreach (<DATA>) {

  chomp;

  my ($text,$ints) = get_text_and_ints($_);

  my $max_int = List::Util::max (@$ints);

  print "/$_/ - has ".(defined $max_int? "maximum of $max_int":"no int
+egers")."\n";

  for (my $i = 0; $i < @$ints; $i++) {
    print " - integer $ints->[$i] is proceeded by /$text->[$i]/\n";
  }

}
__DATA__
ASBSDEC 34 GADVVEEVEETTE 56 IOEOREAK GKJEOG EFEAF 1090 DAFFEE 3762
ASB C 134 PPKOREAK EFEAF 290
What Is The Sqrt Of -1?
This Line Is Only Text
101 Dalmations
42
[download]

#!/usr/bin/perl -w
use strict;

# Read each line one by one
while (my $line = <DATA>) {
    chomp($line);   # Dispense with trailing newline
    # Extract everything that looks like an integer into an array
    my @ints = $line =~ m/(\d+)/g;
    # Sort the array, highest to lowest
    my @sorted_ints = reverse sort { $a <=> $b } @ints;

    # Ouput the line, and the highest integer (1st element of the sort
+ed array)
    print "DATA:$line\nHIGHEST INTEGER:$sorted_ints[0]\n";
}

__DATA__
ASBSDEC 34 GADVVEEVEETTE 56 IOEOREAK GKJEOG EFEAF 1090 DAFFEE 376
ASB C 134 PPKOREAK EFEAF 290
BLAH 99 BLAH 123 FRED 27 BARNEY 427
[download]

DATA:ASBSDEC 34 GADVVEEVEETTE 56 IOEOREAK GKJEOG EFEAF 1090 DAFFEE 376
HIGHEST INTEGER:1090
DATA:ASB C 134 PPKOREAK EFEAF 290
HIGHEST INTEGER:290
DATA:BLAH 99 BLAH 123 FRED 27 BARNEY 427
HIGHEST INTEGER:427
[download]

In some cases, don't we want to use c as well as g so as to advance our pos() within the string regardless of if we match?

I have read that using the regexp variables in that family is really inefficient and likely best avoided when possible.

Assuming a) that there are spaces separating all groups of consecutive digits or letters and b) each group consists only of either digits or letters and c) (crucial for my implementation of the 'more complex' problem), digit groups are never consecutive (meaning, you'll never see a pattern like QKLJB 9234 KJLH 324 9874 in the data). Alternately, if there are consecutive integers, you only care about the most recent letter group (even if it was five groups ago). Also, you only care about the last group of letters before each integer :)

#!blah
#untested!
#use strict, etc.
my $bs; #your big string--how you get the data in there is up 2 u
my ($lms, $lmn); #last matched string,num
my $max = 0;# biggest
while ($bs !~ m/\G\z/ms){
  if ($bs =~ m/\G([[:upper:]]+)\s*/g){#[:alpha:],whatever
     $lms = $1;
  }elsif ($bs =~ m/\G(\d+)\s*/g){#[:alpha:],whatever
     #up to the closing brace before else, 
     #$lms corresponds to the text before this number
     $lmn = $1;
     if ($lmn > $max){
       #at this point, $lms is the text before the biggest int so far
       $max = $lmn;
     }
  }else{
     die "unexpected data near character".pos();
  }
}
[download]

On each line, grab all non-zero integers, sort, return the highest.

print +(sort {$b <=> $a} grep /^\d+$/, split)[0] while <>;
[download]

my $rxPair = qr{(?x) ( [A-Z]+ \s+ \d+ ) };

print
   map { qq{$_->[0]\n     @{ $_->[1] }\n} }
   map {
           my $raLine = $_;
           my $raMax =
              ( sort {$b->[1] <=> $a->[1] } @{ $raLine->[1] } )[0];
           [ $raLine->[0], $raMax ]
       }
   map { chomp; [ $_, [ map { [ split ] } m{$rxPair}g ] ] }
   <DATA>;

__END__
ASBSDEC 34 GADVVEEVEETTE 56 IOEOREAK GKJEOG EFEAF 1090 DAFFEE 376
ASB C 134 PPKOREAK EFEAF 290
BLAH 99 BLAH 123 FRED 27 BARNEY 427
[download]

Here's the output

ASBSDEC 34 GADVVEEVEETTE 56 IOEOREAK GKJEOG EFEAF 1090 DAFFEE 376
     EFEAF 1090
ASB C 134 PPKOREAK EFEAF 290
     EFEAF 290
BLAH 99 BLAH 123 FRED 27 BARNEY 427
     BARNEY 427
[download]

A little late but never mind.

Cheers,

JohnGG