Hashes would also solve your multi-if logic.

Here is a structure outline to get you started:

my (%user_choice, %audit_rec); # Update: Parens added to fix syntax

# Get User input into $user_choice{user}, $user_choice{module} .. and 
+$user_choice{host}

#after reading the record, get it into %audit_rec like this:
 @audit_rec{ qw| time host user module msg  | } = # This is a "Hash-sl
+ice"
          split(']\[|]\s+|^\[',$audit_data);

 # Now, you can compare $user_choice{xxx} with $audit_rec{xxx} , and l
+oop through values for xxx.

# A more advanced technique would be to create a "dispatch table" hash
+ 
# Search for that on this site, if interested.
[download]

Err...

    my %user_choice, %audit_rec;
[download]

gives the warning

    Parentheses missing around "my" list at...
[download]

and the error

    Global symbol "%audit_rec" requires explicit package name at...
[download]

at least for those of us who use strict and warnings.
A word spoken in Mind will reach its own level, in the objective world, by its own weight

This was working fine and i was able to get all the 8 scenarios which i was looking out for, but i felt it is not effective since i had to right 8 loops for this, i just want to know that rather than using 8 If -else looping any better effecient and effective way to do it.

Indeed in Perl there's hardly ever the need to have long sequences of if's, elsif's, etc. But it's not as much a matter of efficiency and effectiveness as much as of clumsiness: your code is hard to follow at all. So what can you do instead? One common way is a dispatch table (look it up in Super Search): that approach is very easy when you have to take an action based on which one of a given set of strings a particular one is. In this case you're having a slightly more complex situation, but at a first glance it seems to me that you can still build unique keys for a hash to use. At a further reading, I notice that all your actions amount to some print's, so the hash needs not even be one of coderefs: it's enough that values are strings. That should make for more compact and more readable code.

Using a bit for each test and a dispatch table may help:

use warnings;
use strict;

my $tName = 'Fred';
my $tHost = 'All';
my $tModule = 'Bobble';
my %dispatch = (
    0 => \&NoMatch,
    1 => \&Name,
    2 => \&Host,
    3 => \&NameHost,
    4 => \&Mod,
    5 => \&NameMod,
    6 => \&HostMod,
    7 => \&NameHostMod,
    );

while (<DATA>) {
    chomp;
    
    my ($name, $host, $mod) = split;
    my $code = $name eq $tName || $tName eq 'All' ? 1 : 0;
    $code |= $host eq $tHost || $tHost eq 'All' ? 2 : 0;
    $code |= $mod eq $tModule || $tModule eq 'All' ? 4 : 0;
    
    $dispatch{$code}->($_);
}

sub NoMatch {
    print "NoMatch\n";
}


sub Name {
    print "Name\n";
}


sub Host {
    print "Host\n";
}


sub NameHost {
    print "NameHost\n";
}


sub Mod {
    print "Mod\n";
}


sub NameMod {
    print "NameMod\n";
}


sub HostMod {
    print "HostMod\n";
}


sub NameHostMod {
    print "NameHostMod\n";
}


__DATA__
Fred Wizzle Tangle
Fred Plonk Bobble
Joe Wizzle Bobble
Bob Fizz Knot
[download]

Prints:

NameHost
NameHostMod
HostMod
Host
[download]

Working, (loosely) tested code:

#!/usr/bin/perl
use strict;
use warnings;

sub grep_dir_of_logs {
  die unless @_ == 4;
  my ( $dir, $sel_user, $sel_host, $sel_mod ) = @_;

  $_ = lc $_ for $sel_user, $sel_host, $sel_mod;

  my $inside_brackets_re = qr{  \[  ( [^[]+ )  \]  }msx;
  my $line_re = qr{
    \A
      $inside_brackets_re
      $inside_brackets_re
      $inside_brackets_re
      $inside_brackets_re
      \s*
      (\S.*?)
      \s*
    \z
  }msx;

  opendir my $dh, $dir
    or die "Can't opendir '$dir': $!\n";
  my @files = grep { !/user.log/ } readdir $dh;
  closedir $dh;

  foreach my $fname ( @files ) {
    my $filename = "$dir/$fname";
    next if -d $filename;

    open my $fh, $filename
      or die "Error opening '$filename': $!";

    while (<$fh>) {
      chomp;

      my ( $date_string, $host, $user, $module, $message )
        = /$line_re/ or die;

      next if $sel_user ne 'all' and $sel_user ne lc $user;
      next if $sel_host ne 'all' and $sel_host ne lc $host;
      next if $sel_mod  ne 'all' and $sel_mod  ne lc $module;

      print "Passed: $_\n";
    }

    close $fh
      or warn "Error closing '$filename': $!";
  }

  return;
}

use IO::Prompt;
grep_dir_of_logs(
  './logs/commonlogs',
  prompt('User  : '),
  prompt('Host  : '),
  prompt('Module: '),
);
[download]