Here's an example showing what you want to do with DBD::CSV:

#!/usr/bin/perl -w

#Define the behaviour of DBI->connect for the entire script
$ENV{DBI_DSN} ||= 'DBI:CSV(RaiseError=>1,AutoCommit=>1):'. join ';',
                  "csv_eol=\n",
                  'csv_sep_char=|',
                  'csv_quote_char=',
                  'csv_escape_char=';
     
use strict;
use DBI; 
use CGI;
  
my $statement = q{
  UPDATE list
     SET title = ?
       , description = ?
   WHERE id = ?
};
  
my $cgi = CGI->new;
  
#Connect to the data source
my $dbh  = DBI->connect;

$dbh->do(
  $statement, 
  {},
  $cgi->param('title'), 
  $cgi->param('description'),
  $cgi->param('id'),
);

$dbh->disconnect; 

print $cgi->header, 'Updated List';

__END__
[download]

Note: The above code assumes that your file name is "list". DBD::CSV can only process files without any extension. Also, if this is going into production you might want turn on Taint checking by appending a T to the first line, as well as validating each of the CGI paramters, possibly using HTML::FormValidator, which is my personal favorite for this.

The great thing about using DBD::CSV is that if you ever switch to using a relational database all the code won't need to change, assuming your schema stays the same. This is why I explicitly define the environment variable $ENV{DBI_DSN} at the top of the script, so that you can easily change it later. Keep in mind this varible globally defines the data source that all the DBI->connect method calls will use, and can be globally set for all your CGI's in Apache's httpd.conf.

As well, I do suggest you look into relational databases, like MySQL or PostgreSQL. They might be better suited for storing this type of information than a flat file.

use CGI;

$q = new CGI;
$upd_id = $q->param('id');
$upd_title = $q->param('title');
$upd_description = $q->param('description');

open F, "file.txt" or die "Can't open file.txt: $!\n";
while (<F>) {
  chomp;
  ($id, $title, $description) = split /\|/;
  if ($id == $upd_id) {
    ($title, $description) = ($upd_title, $upd_description);
    $changed = 1;
  }
  $upd_file .= "$id|$title|$description\n";
}
close F;

if ($changed) {
  open U, ">file.txt" or die "Can't open file.txt: $!\n";
  print U $upd_file;
  close U;
}
[download]

-- tune

open(FILE, "blah");
while (<FILE>) {
      chomp;
      push @array,$_;
}

for( my $i; $i < @array; $i++) {
      ($id,$title,$description) = split(/\|/, $array[$i]);
       if ($id = "THE ID THAT YOU WANT TO UPDATE") {
               splice(@array, $i, 1);
               push @array, "$newid|$newtitle|$newdescription";
        }
}
[download]

{local($^I,@ARGV)=('.bak','file.txt');
while(<>){
#the current line is now in $_, the line in the new edited file is wha
+t ever I will print now(to ARGVOUT which is already select()ed)
if ($.==$linenumberiwanttochange){
chomp;
#edit the line
print "$_\n"; #print the edited line
}else{print} #leave the other lines with no change
}
}
[download]