Re^2: searching for a string w/ a * in any single position?

I think the following will do the trick:

my @chars = map quotemeta,
            split //,
            $word;

my $re = join '|',
         map { local @_ = @chars;
               $_[$_] = '.';
               join '', @_
             }
         0..$#chars;
[download]

Using Regexp::Assemble should be faster:

use Regexp::Assemble qw( );

my @chars = map quotemeta,
            split //,
            $word;

my $ra = Regexp::Assemble->new();

for (0..$#chars) {
   local @_ = @chars;
   $_[$_] = '.';
   $ra->add(join '', @_)
}

my $re = $ra->re();
[download]

Comment on Re^2: searching for a string w/ a * in any single position? Select or Download Code

Replies are listed 'Best First'.
Re^3: searching for a string w/ a * in any single position? by blokhead (Monsignor) on Oct 05, 2007 at 23:06 UTC
Generalizing this approach for Hamming distance > 1, using the combinations iterator from Iterating over combinations: `sub gen_regex { my ($target, $n) = @_; my @chars = split //, $target; my $ra = Regexp::Assemble->new(); my $iter = combinations( $n => [ 0 .. $#chars ] ); while (my @c = $iter->()) { local @_ = @chars; $_[$_] = '.' for @c; $ra->add( join '', @_ ); } $ra->re(); }` [download] blokhead	[reply] [d/l]

Replies are listed 'Best First'.

Re^3: searching for a string w/ a * in any single position?
by blokhead (Monsignor) on Oct 05, 2007 at 23:06 UTC

Iterating over combinations

sub gen_regex {
    my ($target, $n) = @_;

    my @chars = split //, $target;
    my $ra    = Regexp::Assemble->new();
    my $iter  = combinations( $n => [ 0 .. $#chars ] );

    while (my @c = $iter->()) {
       local @_ = @chars; 
       $_[$_] = '.' for @c;
       $ra->add( join '', @_ );
    }

    $ra->re();
}
[download]

blokhead

[reply]
[d/l]