use List::Util qw( max );
my @two_dim = map { [ $array1[$_], $array2[$_] ] }
                  0 .. max( $#array1, $#array2 );
[download]

This assumes you have List::Util (a safe assumption). If one array is longer than the other, the "missing" entries will be undef.

Cute use of "max" there.

I've been getting into "pairwise" lately, myself. From the CPAN module List::MoreUtils:

use Data::Dumper;
use List::MoreUtils qw(pairwise);

my @array1 = qw( a b c d e f );
my @array2 = qw( 1 2 3 4 5 6 );

my @matrix = pairwise { [$a, $b] } @array1, @array2;

print Dumper(\@matrix), "\n";
[download]

perllol, perlreftut, perlref, perldsc. RTFM. HTH. HAND.

my @matrix = (\@array1, \@array2);
[download]

It can be accessed using

$matrix[$col][$row]
[download]

This is what I wanted to post, but I was thinking that maybe I had misunderstood the question. I use this exact thing to 'concat' cols together into a "2 dim array".
--
I used to drive a Heisenbergmobile, but everyone I looked at the speedometer, I got lost.

I think you just answered a slightly different question. Most of us have interpreted the goal like this:

$VAR1 = [
          [
            'a',
            '1'
          ],
          [
            'b',
            '2'
          ],
          [
            'c',
            '3'
          ]
        ];
[download]

Your solution looks like this:

$VAR1 = [
          [
            'a',
            'b',
            'c'
          ],
          [
            '1',
            '2',
            '3'
          ]
        ];
[download]

Most of us have interpreted the goal like this

Yes, I noticed. It would have been silly to post something that was already posted.

There's no rule that says that the first dimension must be rows and the second must be columns. Here code that shows my solution does indeed use @array1 as the first column and @array2 as the second column.

my @array1 = qw( a b c );
my @array2 = qw( X Y Z );

my @matrix = (\@array1, \@array2);

for my $row (0..$#{$matrix[0]}) {
   for my $col (0..$#matrix) {
      print $matrix[$col][$row], "\t";
   }
   print "\n";
}
[download]

a       X
b       Y
c       Z
[download]

Update: Added code.

Why do you want to do this and what have you tried?

In any case, Perl does not have true two dimensional arrays; it has one dimensional arrays where the elements may be references to arrays; see for example perlref).

Something like this works (I presume both arrays are of equal length):

my @matrix;
for my $i (0 .. $#array1) { 
  $matrix[$i] = [ $array1[ $i ], $array2[ $i ] ];  
}

use Test::More qw(no_plan);
is( $matrix[1][1],  $array2[1], "Spotcheck looks good." );
[download]