The inner while is useless, because after the first iteration it will always leave the inner while. You could write it this way instead:

for (3 .. 8) {
        my $pdu_num = $_;
        $pdu_num = 11 - $pdu_num unless defined $order;
        if (@nodes) {
                my $node = shift @nodes;
                $map{$node} = $pdu . '['.$pdu_num.']';
                next;
        }
}
[download]

Now you don't have nested loops anymore, so you don't need the label for next. (Actually you don't need the next at all, because it's the last statement in that loop)

Update: another slightly improved version:

for (3 .. 8) {
        my $pdu_num = $_;
        $pdu_num = 11 - $pdu_num unless defined $order;
        last unless @nodes;   
        my $node = shift @nodes;
        $map{$node} = $pdu . '['.$pdu_num.']';
}
[download]

Moritz,
Thank you. This is more or less exactly what I was looking for. I come from a C-ish background, so the idioms and syntax of Perl leave me stumbling sometimes.
Thanks again!

my @pdu_nums = 3 .. 8;
if ( $order ) {
    @pdu_nums = reverse @pdu_nums;
}

# You could check that @nodes >= @pdu_nums here, too.

foreach my $pdu_num ( @pdu_nums ) {
    my $node = shift @nodes;
    unless ( $node ) {
        die "A horrible death!\n";
    }
    $map{ $node} = join '', $pdu, '[', $pdu_num, '}';
}
[download]

use List::MoreUtils qw( pairwise );

my @pdu_nums = 3 .. 8;
@pdu_nums = reverse @pdu_nums if $order;

%map = { $b => "${pdu}[${a}]" } pairwise @pdu_nums, @nodes;
[download]

(Shrug...)

“Perlish” or not, is it abundantly clear? With a suitable addition of comments, “I think so.”

What I'd really want to see, as “the unfortunate soul who's trying to pick-up after you, after you (poor thing...) got smooshed by that bread-truck,” is a nice, crystal-clear explanation of just exactly where you're headed with that concatenation: $pdu . ''.$pdu_num.''. Where am I gonna see that again? How is that value going to be used? If I needed to change the format of that string, what's gonna break?

You generally don't get Brownie points for being “clever,” nor even for being “efficient.” What enamors you(r memory) to your mourners co-workers is ... simple clarity.

“The computer is really, really fast. We know that.   I'm not (anymore).  ;-)  Don't make me try to ‘figure out’ what you were thinking, nor why.” Do that for me, and I shall forever say about you:   “Such a nice person. Too bad about that bread-truck...”

I see a few things, here.

First, you should always use:

use strict;
use warnings;
use diagnostics; # not everyone puts this in but I think it's helpful
[download]

But that's just general stuff. The big question I have is why use a while (especially with the -- eesh -- next statement) when an if is really what you want? Rewriting this using your (excellent) suggestion of the reformulated for:

foreach my $pdu_num (3 .. 8) 
{
        $pdu_num = 11 - $pdu_num unless defined $order;
        if (my $node = shift @nodes)
        {
                $map{$node} = $pdu . '['.$pdu_num.']';
        }
}
[download]

gives, I think, a much clearer chunk of code

Note that

if (my $node = shift @nodes)
{
    $map{$node} = $pdu . '['.$pdu_num.']';
}
[download]

is not the same as the OP's code. Your code won't process the if if the first element of @nodes is false. Better to use

if (@nodes) {
    my $node = shift @nodes;
    $map{$node} = $pdu . '['.$pdu_num.']';
}
[download]

---

Unless I state otherwise, all my code runs with strict and warnings

YMMV
Chris

Here you can link to Perl docs using [doc://topic]. So your map link is [doc://map].

You can find more linking goodness in What shortcuts can I use for linking to other information? or see Linking on PerlMonks for a list of linking links.

---

Perl is environmentally friendly - it saves trees