use strict;
use warnings;
my $mail = 'xqwertyxyx@gmail.com';

my $count = ($mail =~ tr/x/x/);
print "$count\n";
[download]

use strict;
use warnings;

my $addr = q{xqwertyxyx@gmail.com};

my ( $name ) = $addr =~ m{^([^@]+)};
my %letterFreq;
$letterFreq{ $_ } ++ for split m{}, $name;

print
   map  { qq{$_: $letterFreq{ $_ }\n} }
   sort { $letterFreq{ $b } <=> $letterFreq{ $a } || $a cmp $b }
   keys %letterFreq;
[download]

The output.

x: 3
y: 2
e: 1
q: 1
r: 1
t: 1
w: 1
[download]

I hope this is useful.

Cheers,

JohnGG

C:\>perldoc -q count
Found in C:\Perl\lib\pod\perlfaq4.pod
  How can I count the number of occurrences of a substring within a st
+ring?
    There are a number of ways, with varying efficiency. If you want a
+ count
    of a certain single character (X) within a string, you can use the
    "tr///" function like so:

        $string = "ThisXlineXhasXsomeXx'sXinXit";
        $count = ($string =~ tr/X//);
        print "There are $count X characters in the string";

    This is fine if you are just looking for a single character. Howev
+er, if
    you are trying to count multiple character substrings within a lar
+ger
    string, "tr///" won't work. What you can do is wrap a while() loop
    around a global pattern match. For example, let's count negative
    integers:

        $string = "-9 55 48 -2 23 -76 4 14 -44";
        while ($string =~ /-\d+/g) { $count++ }
        print "There are $count negative numbers in the string";

    Another version uses a global match in list context, then assigns 
+the
    result to a scalar, producing a count of the number of matches.

            $count = () = $string =~ /-\d+/g;
[download]