my @newarray;
for (@array1) {
   push @newarray, $_, $_;
}
[download]

my @newarray = map { $_, $_ } @array1;
[download]

man, I wish I could come up with solutions as fast as you guys.
Thanks Archbishop, that does the trick.
I guess I'd better start going to church more often. I must've strayed from the straight and narrow somewhere.

To do that in-place:

@array1 = (1,33,45,66);
for (reverse 0..$#array1) {
    splice @array1, $_, 0, $array1[$_];
}
print "@array1\n";
__END__
1 1 33 33 45 45 66 66
[download]

_($_=" "x(1<<5)."?\n".q·/)Oo.  G°\        /
                              /\_¯/(q    /
----------------------------  \__(m.====·.(_("always off the crowd"))."·
");sub _{s./.($e="'Itrs `mnsgdq Gdbj O`qkdq")=~y/"-y/#-z/;$e.e && print}

ikegami's solution is simple and elegant, as well as being what I would probably use. But, for the sake of TIMTOWTDI, and to introduce a very handy module, let me suggest:

use List::MoreUtils qw(zip);
my @orig = qw(1 33 45 66);
my @doubled = zip @orig, @orig;
print "@doubled\n";
[download]

@doubled = map({$_, $_} @orig);
[download]

my @array1=(1,33,45,66);
my @array2;
foreach my $element (@array1) {
    push @array2, $element, $element;
}

print @array2;
[download]

Seems to work fine. When you tried that method, did you not use a second array?

If order doesn't matter you can simply:

@array1 = (@array1, @array1);
[download]

Or

push @array1, @array1;
[download]

my @array1=(1,33,45,66);
my @newarray = sort { $a <=> $b } ( @array1 ) x 2;
[download]

Or, if you don't care about the order, as long as similar elements are adjacent (although it doesn't make any difference for your sample data):

my @array1=(1,33,45,66);
my @newarray = sort +( @array1 ) x 2;
[download]

I'm not sure what type of loop you tried, but this produces an array in the order you described:

use strict;
use warnings;

my @array1=(1,33,45,66);
my @array2;

for my $items(@array1){
push @array2,($items,$items);
}

for my $item(@array2){
print "$item\n";
}
[download]