Hi,

Take a look at Text::Table.

Regards,

From a Super Search on 'transpose row column'

Chris

use strict;
use warnings;

# use Data::Dumper;

my %hash = ();

my @array1 = qw(a b c d e);
my @array2 = qw(1 2 3 4 5);

push @{$hash{col1}}, @array1;
push @{$hash{col2}}, @array2;

# print Dumper(%hash);

# Result should look like this:
# col1,col2,
# a,1
# b,2
# c,3
# d,4
# e,5
[download]

If each row of output is built from data in multiple keys of the hash (per your test code), then I don't think you have any choice but to roll your own code that traverses everything and builds up the output.

If you've got arbitrarily many keys in %hash, then you'll likely want something like this:

use strict;
use warnings;

my %hash;

$hash{col1} = [qw(a b c d e)];
$hash{col2} = [qw(1 2 3 4 5)];
$hash{col3} = [qw(q r s t u)];

# Change this so that the keys of %hash
# show up in the order you want them,
# in the output.                                 

my @keys = sort keys %hash;

# Assumes every key of %hash is an
# arrayref with the same number of
# elements in it.  Also note that
# this code destroys %hash, as
# it goes along.  If you don't want
# that, make a copy first.

print join(",", @keys), "\n";

my $ref_key = $keys[0];

while (@{ $hash{$ref_key} })
{
    my @line;

    for my $key (@keys)
    {
        push @line, shift(@{ $hash{$key} });
    }

    print join(",", @line), "\n";
}
[download]

Here's a non-destructive version:

use strict;
use warnings;

my %hash;

$hash{col1} = [qw(a b c d e)];
$hash{col2} = [qw(1 2 3 4 5)];
$hash{col3} = [qw(q r s t u)];

# Change this so that the keys of %hash
# show up in the order you want them,
# in the output.

my @keys = sort keys %hash;

# Assumes every key of %hash is an
# arrayref with the same number of
# elements in it.

print join(",", @keys), "\n";

my $ref_key = $keys[0];

my $count = @{ $hash{$ref_key} };

my $pos = 0;

while ($pos < $count)
{
    my @line;

    for my $key (@keys)
    {
        push @line, $hash{$key}[$pos];
    }

    print join(",", @line), "\n";

    ++$pos;
}
[download]