my @anew = map {
    $_ == 0 || $b[ $_ -1 ] ne $b[ $_ ] ? $a[ $_ ] : ()
} 0 .. $#a;
[download]

thanks for this, I forgot to mention repetitions of other characters in @b are allowed and should not be filtered. Only 'z' repetitions need filtering

my @anew = map {
    $_ == 0
    || $b[ $_ -1 ] ne 'z'
    || $b[ $_    ] ne 'z'
        ? $a[ $_ ] : ()
} 0 .. $#a;
[download]

---

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

"Science is about questioning the status quo. Questioning authority".

In the absence of evidence, opinion is indistinguishable from prejudice.

"Too many [] have been sedated by an oppressive environment of political correctness and risk aversion."

It's more fun with a regular expression! ;)

use strict;
use warnings;

my @a = (  1,9,3,4,5,6,7,2,4,3);
my @b = qw/x y z z a z z z b c/;

# Target: @anew =(1,9,3,5,6,4,3)

my @anew = boil( \@a, \@b );

print "@anew\n";



sub boil {
    my ( $numbers, $letters ) = @_;
    my $pad = '';
    $pad .= $letters->[$_] . $numbers->[$_] foreach 0 .. $#{$numbers};
    {
        no warnings qw/uninitialized/;
        $pad =~ s/(?:z(.)(?:z.)+)|(?:.(.))/$1$2/g;
    }
    return split //, $pad;
}
[download]

I suspect the goal isn't "fun", so bear in mind that the RE approach is fragile if your input data deviates from the format you provided. For example, double-digit numerals will pretty much be the end of the fun unless the RE is modified to accommodate that contingency. But I couldn't resist the opportunity to play with it nevertheless.

a = [ 1,   9,   3,   4,   5,   6,   7,   2,   4,   3 ]
b = ['x', 'y', 'z', 'z', 'a', 'z', 'z', 'z', 'b', 'c']

anew = []
for  i, t in enumerate(zip(a, b)):
    n, c = t
    if i > 0 and c == 'z' and c == b[i-1]:
        pass
    else:
        anew.append(n)
print anew
[download]

[1, 9, 3, 5, 6, 4, 3]
[download]

Another way to do it:

$ perl -le'
my @a = qw( 1 9 3 4 5 6 7 2 4 3 );
my @b = qw( x y z z a z z z b c );
my $char = "z";

my @anew;
for my $i ( 0 .. $#b ) {
    if ( $b[ $i ] =~ ?^$char$? ) {
        push @anew, $a[ $i ];
        }
    elsif ( $b[ $i ] =~ /^$char$/ ) {
        next;
        }
    else {
        push @anew, $a[ $i ];
        reset;
        }
    }
              
print "@anew";
'
1 9 3 5 6 4 3
[download]

This uses an array slice greping the indices of @b that satisfy the criteria.

use strict;
use warnings;

my @a = ( 1, 9, 3, 4, 5, 6, 7, 2, 4, 3 );
my @b = qw{ x y z z a z z z b c };

my @aNew = @a[ grep {
                        ! $_
                        ||
                        $b[ $_ ] ne q{z}
                        ||
                        $b[ $_ - 1 ] ne q{z}
                    } 0 .. $#b ];
print qq{@aNew};
[download]

The output.

1 9 3 5 6 4 3
[download]

I hope this is of interest.

Cheers,

JohnGG

Or using grep:

  my $q = '' ;
  my $i = 0 ;
  @anew = grep { my $p = $q ; $q = $b[$i++] eq 'z' ; !($p && $q) } @a 
+;
[download]

@anew = shrink(\@a, \@b);

sub shrink
{
    my %seen;
    my @ret;

    warn ("input arrays not the same length")
        unless scalar @{$_[0]} == scalar @{$_[1]};

    for my $i ( 0..scalar @{$_[1]} )
    {
        push @ret, $_[0]->[$i]
            unless $seen{$_[1]->[$i]};

        $seen{$_[1]->[$i]} = 1;
    }

    return @ret;
}
[download]

untested:

Unworking :) Produces: 1 9 3 5 4 3 (So did my first attempt. The spec is deceptive.)

---

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

"Science is about questioning the status quo. Questioning authority".

In the absence of evidence, opinion is indistinguishable from prejudice.

"Too many [] have been sedated by an oppressive environment of political correctness and risk aversion."

Yes, I just realized I misread the problem. Doesn't matter. First post get XP that or that way ;)


holli, /regexed monk/

my $i = -1;
my $p = 0;

my @anew = map { $i++; !(/^z$/ or $p = 0) || !$p++ ? $a[$i] : () } @b;
[download]

@a = (1,9,3,4,5,6,7,2,4,3);
@b = ("x","y","z","z","a","z","z","z","b","c");
@a=reverse(@a);
@b=reverse(@b);
foreach $l(0 .. scalar @a){
$next=$b[$l+1];
$next1=$b[$l+2];
if($next ne $b[$l]){
push(@c,$a[$l]);
}
}
print reverse @c;
[download]