here is an example, you can either use the widgets ref and call cget on it or store the text instead.

#!/usr/bin/perl
use Tk;
use strict;
use warnings;

my $mw = tkinit;
my @buttons;
for my $i(0..5){
    push @buttons,
        $mw->Button(-text => $i,
                    -command => sub{
                        print "pressed $i\n";
                        # or use the widget:
                        print "pressed ",
                            $buttons[$i]->cget('-text'),
                                "\n";
                    })->pack;
}
MainLoop();
[download]

But -text is part of an array (@row $row$i) and not not the $i only how can i get the data from an array ($row$i) )

Hi,

this was only meant to be an example on how the Button options can be used. In real world I'd keep data seperated from widgets wherever possible. Also if your data is dynamic I would prefer a Listbox or something similar over dynamically created buttons. That's what most people are used to. But this might well be my very personal taste ;)

#!/usr/bin/perl
use Tk;
use strict;
use warnings;

my $mw = tkinit;
my @buttons;
my @data = qw/foo
              bar
              baz
              this
              that
              whatever
              /;
for my $i(0..5){
    push @buttons,
        $mw->Button(-text => $data[$i],
                    -command => sub{
                        print "pressed $data[$i]\n";
                        print "pressed ",
                            $buttons[$i]->cget('-text'),
                                "\n";
                    })->pack;
}
MainLoop();
[download]

Cheers, Christoph

(Not to be confused with "high aboveyou" :-))

If you want to do this dynamically, so that it will work even after the button's text has changed, you can either use the -textvar option suggested above, or you can construct the button in two steps.

For example, the first step would be something like:

        my $button = $mw->Button(-text => $label);
[download]

    $button->configure(-command => [ \&show_button_label, $button ]);

    -or-

    $button->configure(-command => sub { show_button_label($button) })
+;
[download]

Obviously you can't do this in one step, as $button isn't defined until you have the return value from $mw->Button, and you need to pass $button to the subroutine.

Here's a full example:

#!/usr/bin/perl

# Libraries
use strict;
use warnings;
use Tk;

# User-defined
my @button_labels = (qw(
    Red Blue Green White Yellow Orange
));

# Main program
my $mw = new MainWindow();
foreach my $label (@button_labels) {
    # Note labels are colors, so they can be used for the background
    my $button = $mw->Button(-text => $label, -bg => $label);
    $button->configure(-command => [ \&show_button_label, $button ]);
    $button->pack(-side => "left");
}
MainLoop();


# Subroutines
sub show_button_label {
    my ($button) = @_;
    my $label = $button->cget(-text);
    print "Label for button '$button' is '$label'\n";
}
[download]

           |
           V
my $text = $text->cget( -text ); 
           ^
           |
[download]

Sorry please ignore that lineit was something i tried (didnt work)

Or you could use the -command option to pass arguments to a named subroutine. TMTOWTDI. Also note how $i is used as the loop variable.

...
my @buttons;
for my $i (0..5){
    push @buttons,
        $mw->Button(
            -text => $row[$i],
            -command => [ \&buttonpress, $row[$i] ],
            )->pack;
}

sub buttonpress{
    my $btn = shift;
    print "button $btn pressed\n";
}
[download]