#!/usr/bin/perl
use strict;
use warnings;

my @line01 = ([200900, 202543],
              [202544, 204187],
              [204188, 205831],
              [205832, 207475],
              [207476, 210119],
              [210120, 211763],
              [211764, 213407],
              [213408, 215051],
              );

my $vector = 206000;
for my $i (0 .. $#line01) {
    if ($vector >= $line01[$i][0] and $vector <= $line01[$i][-1]) {
        print $i+1 . "\n";
    }
}
[download]

Note that I have swapped from a series of arrays into an array of arrays (see perllol and/or perlreftut) so the testing code does not need to be repeated 8 times.

If the constraints are different than what I've assumed, you can do this a number of ways, like constructing a hash or regular expressions, which will be of varying appropriateness depending on the actual case.

Worked perfectly :) AWESOME! Thanks!

#!/usr/bin/perl -w
use strict;
use Data::Dumper;

my @lanes = ( [(200900..202543)],
              [(202544..204187)],
              [(204188..205831)],
              [(205832..207475)],
              [(207476..210119)],
              [(210120..211763)],
              [(211764..213407)],
              [(213408..215051)],
        );

my %hash;

my $lane =1;
foreach my $aref (@lanes)
{
   @hash{@$aref} = ($lane) x @$aref;
   $lane++;
}

my $vector = 210121;
print $hash{$vector};  #prints 6
[download]

You could do this using compiled regular expressions for each range as keys to a lookup hash.

use strict;
use warnings;

use 5.010;

my %lanes = (
   1 => [ 200900 .. 202543 ],
   2 => [ 202544 .. 204187 ],
   3 => [ 204188 .. 205831 ],
   4 => [ 205832 .. 207475 ],
   5 => [ 207476 .. 210119 ],
   6 => [ 210120 .. 211763 ],
   7 => [ 211764 .. 213407 ],
   8 => [ 213408 .. 215051 ],
   );

my %lookup =
   map { local $" = q{|}; ( qr{^(?:@{ $lanes{ $_ } })$}, $_ ) }
   keys %lanes;

my @toTest = ( 175924, 203786, 208293 );

OUTER:
foreach my $test ( @toTest )
{
    INNER:
    foreach my $rxCheck ( keys %lookup )
    {
        if ( $test =~ $rxCheck )
        {
            say qq{$test -- $lookup{ $rxCheck }};
            next OUTER;
        }
    }
    say qq{$test -- No match!};
}
[download]

The output.

175924 -- No match!
203786 -- 2
208293 -- 5
[download]

I hope this is of interest.

Here is another version using the arrays as listed in OP and a reference that loops through each array. You could add logic to break out of the loops once the value is found.

Updated again... left out $found declaration and initialization (fat fingers).

#!c:\perl\bin\perl.exe

use strict;
use warnings;

my @lane01_1 = (200900..202543); 
my @lane01_2 = (202544..204187);
my @lane01_3 = (204188..205831);
my @lane01_4 = (205832..207475);
my @lane01_5 = (207476..210119);
my @lane01_6 = (210120..211763);
my @lane01_7 = (211764..213407);
my @lane01_8 = (213408..215051);

my $arrayref;
my $buildvar;
my $vector = 209456;
my $found = 0;

while(! $found) {
   $buildvar = "\\\@" . "lane01_" . $i;
   $arrayref = eval($buildvar);
   if(! defined @$arrayref) {
      print("vector: $vector not found\n");
      last;
   }
   for(my $j = 0; $j < (scalar(@$arrayref)); $j++) {
      if($$arrayref[$j] == $vector) {
         print("lane # is $i\n");
         $found = 1;
      }
   }
   $i++;
}

OUTPUT:
lane # is 5
[download]

Update #1: Removed some values from testing

Update #2: Included output.

Update #3: Couldn't take it - replaced outer for loop with a while loop and a bool. This also required a test to make sure @$arrayref references a valid array. If it's not, then there is no match for $vector. Original for loop included below.

for (my $i = 1; $i <= 8; $i++) {
   $buildvar = "\\\@" . "lane01_" . $i;
   $arrayref = eval($buildvar);
   for(my $j = 0; $j < (scalar(@$arrayref)); $j++) {
      if($$arrayref[$j] == $vector) {
         print("lane # is $i\n");
      }
   }
}
[download]