You're on the right track, but you're keeping only one total, whereas there are more than one columns. Suddenly I have this nagging feeling that an array to keep the sums would be useful.

A very small hint:

while (my $line = <>) {
    my @column = split(' ', $line); 
#    $sum[$_] += $column[$i] for 0..$#column;
# line corrected by mjscott7202 into:

    $sum[$_] += $column[$_] for 0..$#column;

}
[download]

That's two hints, actually. Or three, depending on how you look at it. Anyway, on a side note: you'll also want to use strict; and use warnings;. This will help you catch a lot of errors, typoes, and other mistakes.

Shouldn't that be:  $sum[$_] += $column[$_] for 0..$#column;

I presume the $i should actually be the default index variable $_ generated by the for loop?

You're quite right. Initially I wrote it with a for my $i (...) {...} loop but then thought I could do it with a postfix for. Forgot to replace that one instance of $i with $_. Corrected. Thank you :)

This should work

#!/usr/bin/perl

use strict;
use warnings;

open IN, 'data.txt' or die$!;
my @colSum;

while(<IN>){
    chomp($_);
    my @colArray = split(/\s/,$_);
    for(my $i = 0; $i <= $#colArray; $i++){
        $colSum[$i] += int($colArray[$i]); 
    }
}

foreach my $ j(0 .. $#colSum){
    print "Sum for column",$j,"is: ",$colSum[$j],"\n";
}
[download]

What you were trying to do was not correct. You were taking the entire line and was adding to another line. $_ takes it as a string and if you convert into a int type also then it will not convert according to your logic because there will be spaces between them. Therefore, you need to take it into an array and compute the sum of column by adding to the previous element using loop.

Removed!

Sorry, I misread the question. :-(

OK, (after reading the question properly) here's another way to do it. :-)

#!perl

use 5.12.0;
use warnings;

use List::Util qw{sum};

my @table = ();

while (<DATA>) {
    push @table, [ split ];
}

for my $col (0 .. $#{$table[0]}) {
    say qq{Column $col = }, sum map { $table[$_][$col] } (0 .. $#table
+);
}

__DATA__
1 2 3 4 5 6
1 2 3 4 5 6
[download]

Output:

$ column_sum.pl
Column 0 = 2
Column 1 = 4
Column 2 = 6
Column 3 = 8
Column 4 = 10
Column 5 = 12
[download]

Update: My apologies if anyone noticed this kept changing and wondered what the hell was going on. My main intent was just to highlight the sum function in List::Util.

It has been pointed out to me that I should have used <strike> instead of simply deleting the code I originally posted.

My original solution calculated the sum of the column items in each row rather than the sum of each column. The comment was that even though this didn't answer the OP's question it was nonetheless interesting code that others might like to see.

So, rather than doing any more (possibly confusing) updates to my last post, I've posted my original offering separately here.

#!perl

use 5.12.0;
use warnings;

use List::Util qw{sum};

my $total = 0;

while (<DATA>) {
    $total += sum split;
}

say $total;

__DATA__
1 2 3 4 5 6
1 2 3 4 5 6
[download]

Outputs:

$ row_sum.pl
42
[download]

Enjoy!

-- Ken

#!/usr/bin/perl ##Assume the following array having data in the matrix form. @a=( qw(1 2 3), qw(1 2 3), qw(1 2 3) ); for (my $j=0;$j <= ($#{$a[0]}) ;$j++) { my $sum=0; print "=======\n"; for(my $i=0;$i<=$#a;$i++) { print "$i$j=$a$i$j \n"; $sum+=$a$i$j; } push @a, $sum; print "\n$sum\n"; } print "\naaaa===\n@a\n";

#!/usr/bin/perl
##Assume the following array having data in the matrix form.
@a=(
    [qw(1 2 3)],
    [qw(1 2 3)],
        [qw(1 2 3)]
    );

 for (my $j=0;$j <= ($#{$a[0]}) ;$j++)
 {
 my $sum=0;
 print "=======\n";
    for(my $i=0;$i<=$#a;$i++)
        {
        print "[$i][$j]=$a[$i][$j] \n";
        $sum+=$a[$i][$j];
        }
     push @a, $sum;
     print "\n[$sum]\n";
 }
print "\naaaa===\n@a\n";
[download]