$_ is a variable that is set to whatever Perl thinks you are most likely to want to use as a default command/subroutine argument. Many Perl commands will automatically use whatever value is assigned to $_ so you don't have to do so much typing:

   defined       #same as defined($_)
   print         #same as print STDOUT $_
   /\sjackson$/  #same as $_ =~ /\sjackson$/
[download]

The actual value assigned to $_ depends on the context because what you are "most likely to want to use as an argument" usually depends on what you are doing in your code at that moment.

In a for loop $_ is the current array element.

When using grep or map it is also the current array element:

  @only_defined = grep { defined($_) } @somearray;
  %hash_defined = map { $_ => 1 } @only_defined;

  #and since $_ is the default argument, you can also write
  @only_defined = grep { defined } @somearray;
  @only_begins_with_a = grep { /^a/ } @somearray;
[download]

If you are reading from a file using the <> operator, it is the most recently read line, e.g.

  while (<STDIN>) {
    chomp              # same as chomp $_
    if (/^#/) {....}   # same as if ($_ =~ /^#/) { ....}
  }
[download]

You don't have to use $_ for loops. In fact, for production code, it is a good idea not to because every so often something you are doing inside the for loop might unexpectedly reset $_ (it shouldn't but you don't always have control over other people's code and how they use things like $_. The inside of loops often makes calls to other people's code). For example, your loop above could also have been written:

#Note this code still won't work - see sherm's explanation below.

foreach my $name (@myNames)
 {
     if($name =~ "jackson")
     print $name . "\n";     #sic - should be { print $name . "\n" }
 }
[download]

The same caution about $_ also applies to $_ when reading from an input stream or any other use of $_. If you are doing something complicated, it is best to assign $_ to a variable with a name you control and to use that variable instead of $_. Thus a better way to write the code reading from STDIN above would be

  while (my $line = <STDIN>) {
    chomp $line;
    if ($line =~ /^#/) {....}
  }
[download]

Update: added comment about non-working code and referenced sherm's explanation below.

Okay, first things first: What is $_? Simply put, it's a variable. In that sense, it's no different than $foo or $bar. What makes it special is that it's used it by default in many situations, if you don't supply another variable. The chomp() function, for example, which removes $/ (which is typically \n) from the end of one or more variables. If you write chomp($foo), it will affect $foo; but if you write chomp(), it will affect $_ by default.

Another example of using $_ is the foreach() loop in your own code. Foreach creates a local alias for each element in the given list. Because you didn't specify a name for that alias, it defaults to using $_. But, you could have written that as "foreach my $thisName (@myNames)", in which case the $thisName variable would be used as the alias instead.

The problem in your loop actually isn't the pattern match - that does just what you think it should, matching only strings that contain "jackson". The problem is that you've left out the curly braces. Unlike C, Perl's curly braces are always required for compound statements. So you need to write that if() like this:

if ($_ =~ "jackson") {
    print $_ . "\n";
}
[download]

That's only relevant when you're using a statement that requires a code block, though, as in "if() { ... }" - there are alternatives you can use that wouldn't require one, such as a logical-and operator or statement modifiers. (Note that these examples take advantage of the fact that the match operator m// also defaults to matching against $_!)

m/jackson/ and print $_ . "\n"; # logical-and
print $_ . "\n" if (m/jackson/); # statement modifier
[download]

for (@names) {
   # Use $_ here
}
[download]

is simply the same as

for $_ (@names) {
   # Use $_ here
}
[download]

You can use a different variable if you want

for my $name (@names) {
   # Use $name here
}
[download]

There are a couple of tricks to help you answer that. Since $_ has been defined, start with that. Using perldoc, just enter

perldoc -v '$_'
[download]

$_ is a perl builtin variable, but how would you know that? You can get a complete list of builtin variables by using B::Keywords:

#!/usr/bin/perl

use strict;
use warnings;
use B::Keywords qw(:all); 

print join "\n", @Symbols, "\n";
[download]

perldoc -f my
[download]

perl /usr/lib/perl5/5.8.8/Pod/Functions.pm
[download]

Update: ELISHEVA has reminded me that you can access perlop by entering doc://perldoc in the perlmonk's search bar.

I am sure the answers to your questions are in more or less every Perl related FAQ. $_ will be documented in perlvar, =~ will be in perlop, but this is a quiet Sunday evening, and I enjoy helping out Novice monks.

I think $_ has been adequately explained by ELISHEVA, I especially liked her explanation of it as ...whatever Perl thinks you are most likely to want...

=~ is the operator that binds a perl scalar variable to a regular expression. If you are not using $_, This is usually how you tell perl what variable you want to test against the regular expression. Consider ELISHEVA's second example:

  while (<STDIN>) {
    chomp              # same as chomp $_
    if (/^#/) {....}   # same as if ($_ =~ /^#/) { ....}
  }
[download]

With explicit variables this could be written:

  while (my $line = <STDIN>)
  {
    chomp $line;             # same as chomp $_
    if ( $line =~ m/^#/ )
    {
      # Action on $line.
    }
  }
[download]

In this form we have made the code a good deal clearer, and easier to understand by a novice, But because we are no longer using the $_ default variable we need to tell perl what variable the regular expression should be matched with. The whole $variable =~ m/regexp/ returns true if the variable matches regular expression, or false otherwise, so within an if statement it allows you to select only lines that match.

The other use for the =~ operator is for substitutions. If you write:

$line =~ s/^#/# Comment /;
[download]

Then you substitute everything that matches on the left with the string on the right. In this case any lines in the input that start with hash will have 'Comment' prepended.

• To match for jackson you can say m"jackson" or /jackson/. With slashes the m is assumed.
• You don't need the $_ =~ because $_ is the assumed operand of a match.
• The dot is concatenation. If you don't like it you can say "$_\n"

the =~ operator is part of a regular expression. One of the most powerful features I know. Check perlre, perlreref, perlrebackslash, perlrecharclass, perlreref, perlrequick or perlretut.

Not at all. It relates to the match, substitution and tr operators, not regular expressions. Some of those operators take a regular expression for argument, but that's unrelated to «=~».

---

«=~» is the means by which one specifies the operand (argument) for some operators.

$x =~ m/.../         # Matches against $x
$x =~ s/.../.../     # Modifies $x
$x =~ tr/.../.../    # Modifies $x
[download]

«/.../» is short for «m/.../».

Operators that support «=~» default to using «$_» if «=~» isn't' used. For example, «/.../» is short for «$_ =~ /.../».

The match operator is implied if the RHS of «=~» is an expression, so «$x =~ "pat"» means «$x =~ /pat/» and «$x =~ $pat» means «$x =~ /$pat/».

my @myNames = ('Larry jackson', 'Curly jackson', 'Moe Sanders','Jackso
+n Something','jackson',);   

# our list of names, note that I added a few more

 print "Who's on the list:\n"; 

 foreach $fullname (@myNames) {             

        # $fullname contains each name in @myNames one by one

        @array = split (/\s+/,$fullname);   

        # lets split the name based on a whitespace character, 
        # in our case, a space, \s

        if (scalar @array > 1) {       

        # if the number of elements in the array @array 
        # is more than one, which it should be, then 
        # check the second element, like this

           if($array[1] =~ /jackson/i) {   

            # the "i" indicates a case-insensitive match,  
            # Jackson is same as jackson

                print "$fullname\n"; # go ahead and print 

           }

        }

 }
[download]