Sorry, I was trying as much as possible to do it myself and following tips to try and learn. Thanks for helping thus far. Here are a few lines:

"Barber Shop: NW, 147-2220, Washington 992,,,,,
,"Lawrence, Jerry A.",Buzz,,Clean,Cash,,
,"Wallace, Bob W.",Caesar,,High,Credit,,
,"Anthony, Ronald",Caesar,,Close,Cash,,
,"Nelson, Dwight R.",Buzz,,Clean,Check,,
,"Jamison, Jeff S.",Caesar,,High,Credit,,
,"Favors, Eric S.",Shave,,Skin,Cash,,
,"Williams, Herb C.",Fade,,High,Check,,
,"Carter, Shaun ",Caesar,,Low,Cash,,
[download]

Once again, all I want to do is save the name into $last $first $mid A few people don't have middle initials though, so I'm not entirely sure how to handle that..

What do you think of this?

use Modern::Perl;

while (<DATA>) {
    my ($last, $first, $mid) = /^,"([^",]+),\s([^\s"]+)\s?([^"]*)/;
    say "LAST: $last FIRST: $first MID: $mid" if $last;
}

__DATA__
"Barber Shop: NW, 147-2220, Washington 992,,,,,
,"Lawrence, Jerry A.",Buzz,,Clean,Cash,,
,"Wallace, Bob W.",Caesar,,High,Credit,,
,"Anthony, Ronald",Caesar,,Close,Cash,,
,"Nelson, Dwight R.",Buzz,,Clean,Check,,
,"Jamison, Jeff S.",Caesar,,High,Credit,,
,"Favors, Eric S.",Shave,,Skin,Cash,,
,"Williams, Herb C.",Fade,,High,Check,,
,"Carter, Shaun ",Caesar,,Low,Cash,,
[download]

Output:

LAST: Lawrence FIRST: Jerry MID: A.
LAST: Wallace FIRST: Bob MID: W.
LAST: Anthony FIRST: Ronald MID: 
LAST: Nelson FIRST: Dwight MID: R.
LAST: Jamison FIRST: Jeff MID: S.
LAST: Favors FIRST: Eric MID: S.
LAST: Williams FIRST: Herb MID: C.
LAST: Carter FIRST: Shaun MID:
[download]

CountZero

A program should be light and agile, its subroutines connected like a string of pearls. The spirit and intent of the program should be retained throughout. There should be neither too little or too much, neither needless loops nor useless variables, neither lack of structure nor overwhelming rigidity." - The Tao of Programming, 4.1 - Geoffrey James

 #!/usr/local/bin/perl
 open (MYFILE, 'shoplist.csv');

my $i=0;
while (<MYFILE>) {
     chomp;
     if($i == 0)
      {
          $i++;
           next;
       }

     if (/\"(.*)\"/) {
         my ($first,$last)=split('\s',$_);                         
             
         print "$last $first\n";
     }
 }
 close (MYFILE);
[download]

Lawrence, Jerry A.
Wallace, Bob W.
Anthony, Ronald
Nelson, Dwight R.
Jamison, Jeff S.
Favors, Eric S.
Williams, Herb C.
Carter, Shaun
[download]

#!/db/bin/perl -w

use strict;
use warnings;

my $filename = $ARGV[0];


open FILE, $filename or die $!;

my $i = 0;
while(<FILE>)
{
        if($i == 0)
        {
                $i++;
                next;
        }
        chomp;
        if (/\"(.*?), (.*?)[" ]((.*?)\")?/)
        {
                my $last = $1;
                my $first = $2;
                my $mi  = $4;
                if(defined $mi)
                {
                        print "$last, $first $mi\n";
                }
                else
                {
                        print "$last, $first\n";
                }
        }

}

close FILE;
[download]

That works awesomely! May I ask, what the first if clause does?

if($1 == 0)

I took the regex match and the printing code and replaced the code I had before and it worked marvelously, thanks so much. Now I need to play with the $last $first $mi variables and figure out how to output them into a javascript array. I might be back later on this evening unless I can figure it out.

You stated that you didn't want to print the first line. Notice the variable $i is initialized to 0. That if clause checks if the variable $i is equal to 0. Since we initialized it to 0, it enters the clause. The first line increases the variable $i to 1. Then it tells the while loop to skip to the next iteration. Now when you come to the clause this time, it skips it and continues to the rest of the while code because variable $i now equals 1.

By the way, glad you're asking questions. The more you ask now, the less you'll ask in the long run.

Double quotes are not magic in a regex, so you do not have to escape them.

If you want to skip the first line of your loop, why not simply do a <FILE> just before the loop? That reads the first line and discards it.

You do not need a chomp inside the loop. Your regex extracts the fields well before it reaches the end of the string.

Always use a three argument open. What do you think will happen when someone maliciously enters >myfile.txt as the filename argument? Indeed, bye bye file contents!

CountZero

A program should be light and agile, its subroutines connected like a string of pearls. The spirit and intent of the program should be retained throughout. There should be neither too little or too much, neither needless loops nor useless variables, neither lack of structure nor overwhelming rigidity." - The Tao of Programming, 4.1 - Geoffrey James

Good points. 3/4 of them were due to me copying the OP's code with barely a glance.