Fire up the Tk demo program widget, and look through the examples.

See also http://perltk.org, and http://www.perl.com/pub/1999/10/perltk/

Which part are you having trouble with?

You seem to know how to construct a GUI at startup, adding elements to it at runtime is not different than at startup. You can keep GUI elements in arrays, just like any other objects.

But how many time Im going to press button and how many element can i keep it in array is unknown right? Please correct me if Im wrong here.

You can keep as many elements in an array as you have memory for storage. So just add one every time the user presses the button. (And maybe remove one if the user presses a different button).
Perl 6 - second systems done right

I actually did not get the GUI element. This is my line of code $AddMoreTarget=$AddtargetBtnConfig->Button(-text=>"Add Host",-font=>"bold",-background =>"blue", -foreground => "white",-width=>20, -command=>\&AddHost, $AddtargetConfig1)->pack(); Where the "AddHost" will add the text box.Can you please point out the element which I can put into the array?

When you want to dynamically add a bunch of widgets, like a Text or Canvas, it's usually best to put them into a Scrolled Pane. Here is a simple example.

#!/usr/bin/perl
use warnings;
use strict;
use Tk;
use Tk::Pane;

my $mw = MainWindow->new;
$mw->geometry('800x600+100+100');

$mw->fontCreate('big',
     -weight=>'bold',
     -size=> 18
    );


my $count = 0;

# hash to hold the text widgets
my %text;

my $abutton = $mw->Button( -text => 'Add New Text Widget',
              -bg => 'lightyellow',
              -command => \&add,
              -font => 'big'
)->pack(-fill=>'x');


# Scrolled Pane to be the overall container
my $sp = $mw->Scrolled('Pane',
    -scrollbars => 'osoe',
)->pack(-fill=>'both', -expand=>1 );

# a simple text inserter to all text widgets
my $repeater = $mw->repeat(2000,\&insert );

MainLoop;

sub add{
  my $num = $count++;

  # make a frame to lock in the scrolled text to the scrolled pane
  my $frame = $sp->Frame()->pack(-fill=>'x', -expand=> 1);

  $text{$num} = $frame->Scrolled('Text',
                 -background=>'lightsteelblue',
         -foreground=>'black',
                 -font => 'big',
                 -height => 15, # how many lines are shown
                 -width => 100, # how many characters per line
                 )->pack(-fill=>'both', -expand=>1);
 

 }


sub insert {
   my $data = rand 100000;

   foreach my $num (keys %text){
     $text{$num}->insert('end',"text number $num-> ". $data);
     $text{$num}->insert('end',"\n");
     $text{$num}->see('end');
  }

}
[download]