use warnings;
use strict;
use XML::Twig;

my $str = <<EOF;
<li>
  <p>
   Some <b>text</b>
  </p>
</li>
EOF

my $t = XML::Twig->new(
    twig_handlers => {li => \&li},
    pretty_print  => 'indented',
);
$t->parse($str);
$t->print();

sub li {
    my ($t, $elt) = @_;
    for my $p ($elt->children('p')) {
        for my $c ($p->cut_children()) {
            $c->paste($elt);
        }
        $p->delete();
    }
}

__END__

<li><b>text</b>
   Some </li>
[download]

Hi Canon, getting closer, but for some reason the children are coming out in the wrong order (reversed?):

Original:

<li class="c2">
	<p class="Number1">In the XYZ pane, select the <span class="c1">PageID</span> ruleset and click the <span class="c1">Lock/Unlock ruleset</span> button. Then expand the
	<span class="c1">PageID</span> ruleset to view the two rules.</p>
</li>

Result:

      <li class="c2"> ruleset to view the two rules.<span class="c1">PageID</span> button. Then expand the
            <span class="c1">Lock/Unlock ruleset</span> ruleset and click the <span class="c1">PageID</span>In the XYZ pane, select the </li>

Thoughts?

To answer my own question, using reverse seems to fix the problem:

    for my $p ($elt->children('p')) {
        for my $c (reverse($p->cut_children())) {
            $c->paste($elt);
        }
        $p->delete();
    }
[download]

I don't understand why it's needed, but it works.

use strict;
use XML::Rules;

my $parser = XML::Rules->new(style => 'filter', rules => {
    _default => 'raw',
    p => sub { return $_[1]->{_content}},
});

$parser->filter(\*DATA);

__DATA__
<li>
  <p>
   Some <b>text</b>
  </p>
</li>
[download]

If you wanted to remove only <p> directly inside <li>, the code would look like this:

use strict;
use XML::Rules;

my $parser = XML::Rules->new(style => 'filter', rules => {
    _default => 'raw',
    p => sub {
        if ($_[2][-1] eq 'li') {
            return $_[1]->{_content};
        } else {
            return $_[0] => $_[1];
        }
    },
});

$parser->filter(\*DATA);

__DATA__
<root>
<li>
  <p>
   Some <b>text</b>
  </p>
</li>
  <p>
   Other <b>text</b>
  </p>
</root>
[download]

The $_[2] is a reference to an array containing the names of the opened tags, so the condition just checks whether the enclosing tag of the currently processed <p> is <li>.

First, a few comments on your code: delete completely deletes the element, including its descendants. So you should do this after moving the children. Then you cannot paste an element that's already part of a tree. You need to cut it, then paste it. Or in short, to move it. move, like paste, needs a position and a referent as arguments: $c->move( before => $p) would work.

Also, I am not sure of the test on $p->parent('li'): it will try to find an li ancestor to $p, which may, possibly, find false positives (a p buried in a table within a li), so you probably want $p->parent->tag eq 'li', or $p->parent->is( 'li')).

That said, try $p->erase if( $p->parent->is( 'li')), that might just do what you want.

Thanks -- yeah I noticed that 'parent' and 'ancestor' seem to be the same thing -- thanks for clarifying how to eliminate the false positives. Scott

for //li/*  mv text() replace . ;
[download]

for //li/*  {
    xmove (text()|*) after . ;
    rm . ;
}
[download]

for //li/* xmove (text()|*) replace . ;
[download]

Here is one way to do this with XML::LibXML.

#!/usr/bin/perl
use warnings;
use strict;
use XML::LibXML;

my $xmlfile = 'test.xml';

my $parser = XML::LibXML->new();
my $doc    = $parser->parse_file($xmlfile);

my ($li_node) = $doc->findnodes("//li");

my ($p_element) = $doc->findnodes("//li/p");

foreach ($p_element->childNodes) {
    $li_node->appendChild( $_ );
}
$li_node->removeChild( $p_element );
    
print $doc->toString;
[download]

Contents of test.xml:

<?xml version="1.0" encoding="utf-8"?>
<li>
  <p>
   Some <b>text<c1> here</c1></b>
  </p>
</li>
[download]

Result:

<?xml version="1.0" encoding="utf-8"?>
<li>
  

   Some <b>text<c1> here</c1></b>
  </li>
[download]