tobeythorn:

Here's a simple example:

$ cat foo.pl
use strict;
use warnings;
my @AoH;

# Build the AoH
while (<DATA>) {
    chomp;
    last if /^\s*$/;
    my ($file, $path) = split /:/;
    push @AoH, { path=>$path, file=>$file };
}

# Print the data
for (@AoH) {
    print "PATH:", $$_{path}, ", FILE:", $$_{file}, "\n";
}
__DATA__
baz:/foo/bar
gunk:/tmp/roboticus

$ perl foo.pl
PATH:/foo/bar, FILE:baz
PATH:/tmp/roboticus, FILE:gunk
[download]

...roboticus

When your only tool is a hammer, all problems look like your thumb.

The problem is that ${metadata}{'path'} (which is the same thing as $metadata{path}, since curly brackets around the variable name only serve to disambiguate when it's not clear where the variable name ends), represents a value in the hash %metadata, not a value in a hash pointed to by the scalar reference $metadata. If you were using strict, it would have complained there because %metadata doesn't exist. Presumably you aren't using strict, so it happily creates %metadata on the fly, puts your keys and values in it, and then your other hash that $metadata points to is empty when you push that onto @files.

To access the values in a hash pointed to by a scalar reference, use this format: $metadata->{path}

Like this: $metadata->{path} = $filepath_rs;

@files = ();

sub filer
{
    $filepath_rs = $File::Find::name;
    if(-f $filepath_rs)
    {
        $metadata = {}; #should instantiate a new hash object and retu
+rn a scalar reference.
        $metadata->{path} = $filepath_rs;
        print $metadata->{path}; #prints out fine
        push @files, $metadata; #should add reference to hash to array
+.
    }
}


find(\&filer, $mydir);

foreach my $file (@files)
{
    print $file->{path}; #???
}
[download]

Thank you all. The -> notation is great, and as a c programmer, makes me feel at home. I've turned strict on and it now works. Unfortunately, I am currently blind because some modrewrite in some .htaccess file is preventing me from seeing debug info.

Perhaps you can tell me why, using the -> notation, keys do not go in quotes? In the following, what is the type of mykey? It doesn't have quotes, nor a type prefix such as $, %, or @.

$myhash_ref->{mykey};

why, using the -> notation, keys do not go in quotes?

They do -- the quotes are just optional. You might need the quotes if the key name collides with a built-in function such as 'shift'

In the following, what is the type of mykey? $myhash_ref->{mykey};

That would be equal to the string 'mykey'

Thanks vroom. I will be explicit then and use the quotes.

#!/usr/bin/perl -w
use strict;
use File::Find;
use Data::Dumper;

my @files = ();  #will be an Array of Hashes
my $odd =1;

sub filer
{
    my $filepath_rs = $File::Find::name;
    return unless -f $filepath_rs;
  
    push(@files, {file=>$filepath_rs, OddEven => $odd}); 
    $odd ^= 1;
}

find(\&filer, 'C:/temp');

print Dumper \@files;
[download]

#!/usr/bin/perl -w
use strict;
use File::Find;
use Data::Dumper;

my @files = ();  #will be an Array of Hashes
my $odd =1;

sub filer
{
    my $filepath_rs = $File::Find::name;
    return unless -f $filepath_rs;
    
    my %metadata;
    $metadata{file} = $filepath_rs;
    $metadata{OddEven} = $odd;
  
    push(@files, \%metadata); 
    $odd ^= 1;
}

find(\&filer, 'C:/temp');

print Dumper \@files;
[download]