What you describe is a CSV (character separated value) file and there are a plethora of modules available to handle that format for you. A good starting point is Text::CSV. Using such a module your problem turns into:

use strict;
use warnings;
use Text::CSV;

my $dataStr = <<DATA;
1/1/1923\tFirst entry\t-23.45
2/2/1924\t"Second entry with a long multi-line description.
This is parsed fine using Text::CSV, but I bet your regex chokes."\t23
+.23
DATA

my $csv = Text::CSV->new({sep_char => "\t", binary => 1});

open my $dataIn, '<', \$dataStr;
while (my $row = $csv->getline($dataIn)) {
    my ($date, $description, $value) = @$row;
    
    print "Value is $value\n";
}

close $dataIn;
[download]

Prints:

Value is -23.45
Value is 23.23
[download]

As an aside the regex magic you want is the ? modifier:

use strict;
use warnings;
use Text::CSV;

my $dataStr = <<DATA;
1/1/1923\tFirst entry\t-23.45
2/2/1924\t"Second entry with a long multi-line description.
This is parsed fine using Text::CSV, but I bet your regex chokes."\t23
+.23
DATA

open my $dataIn, '<', \$dataStr;
while (my $line = <$dataIn>) {
    next if $line !~ /(-?\d*\.\d*)/;
    
    print "Value is $1\n";
}

close $dataIn;
[download]

Prints:

Value is -23.45
Value is .
Value is .
[download]

which you will note still fails in nasty ways because the regex isn't near sufficient to extract the data you want. However, there are a huge number of errors in the regex you show so you absolutely must go read some of the regex documentation: perlretut, perlre and perlreref for a start.

        _____________________ date
       /       ______________ desc
      /       /       _______ amount
     /       /       /
  ------  ------  ------
/^[^\t]*\t[^\t]*\t[^\n*]\n\z/
[download]

You want to remove the amount, so

s/^[^\t]*\t[^\t]*\t\K[^\n*]//;     # 5.10+

s/^([^\t]*\t[^\t]*\t)[^\n*]/$1/;   # Any version
[download]

RobertJ:

You may simply be working too hard. If your format is just as described, and you don't have the TAB character anywhere in your data, you could probably just use something like (untested):

while (my $line = <INFILE>) {
   my ($date, $description, $amount) = split /\t/, $line;
   if (defined $amount) {
      print OUTFILE $amount;
   }
   else {
      # Amount not found...
   }
}
[download]

If you're really wanting to use a regular expression, though, something like this might be more appropriate:

while (my $line = <INFILE>) {
   if ($line =~ /(-?\$\d*\.\d*)/) {
      print OUTFILE $1, "\n";
   }
   else {
      # Amount not found...
   }
}
[download]

In the regex, '-?' means "Maybe a minus sign". I left out the square brackets because they didn't really add anything just make a mess of things.

...roboticus

Update: Corrected square bracket comment. (Kudos to GrandFather for the catch.)

When your only tool is a hammer, all problems look like your thumb.

Actually leaving out the square brackets is required! Not so much they didn't add anything as, they subtracted a lot! By now maybe the OP has read the regex docs and will realise that the square brackets denote a set of characters which matches just one character in the string being matched. It looks like the OP was thinking [] is equivalent to (). It's not.

True laziness is hard work

my $amt = ((split(/\t/,$data))[2]);
[download]

my ($amount) = $line =~ /([^\t]+)$/;
[download]

use strict;
use warnings;

while (<DATA>) {
    if (m/\t(-?\$\d+.\d+)$/) {
        print "$1\n";
    }
}

__DATA__
12-31-2000    description    $44.44
12-31-2000    description    -$44.44
[download]