Swap the positions in the file of the last two cases to get one clue. Once you've done that, print out what gets put into @a for another clue.

Really interesting! I changed the script to:

#!/usr/bin/perl
use strict;
use warnings;

my $a="  456 789 123 456 789  ";
my $count;
$count = $a =~ /\d+/g ;
print "$count\n";

my @a = $a =~ /\d+/g ;
$count = @a;
print "@a\n";
print "$count\n";

$count = () = $a =~ /\d+/g ;
print "$count\n";
[download]

The results are:<\p>

1
789 123 456 789
4
5
[download]

Could you please advise why the 1st digit group is gone the first time i call $a =~ /\d+/g ?

When you use the g modifier, it keeps track of its last match. In the first RE (scalar context), 456 is matched: your count indicates a single match (see code below for actual value). In the second RE (list context), the remaining four sets of digits are matched. You can use pos to reset the last match position.

$ perl -Mstrict -Mwarnings -e '
> my $a="  456 789 123 456 789  ";
> my $count;
> $count = $a =~ /\d+/g ;
> print "$count\n";
> print "${^MATCH}\n";
> pos($a) = 0;
> my @a = $a =~ /\d+/g ;
> $count = @a;
> print "@a\n";
> print "$count\n";
> '
1
456
456 789 123 456 789
5
[download]

${^MATCH} is described in perlvar.

-- Ken

Hint: look for the phrase "search position" in perlop. Also consider that scalar global matches are typically used in loops, for example

for my $match ($a =~ /\d+/g) {
   print "$match\n"
}
[download]

Really i could not understand but the code

$count = $a =~ /\d+/g ;
vs.
$count = () = $a =~ /\d+/g ;
[download]

is an issue.

The second print statement print '4', because you have used /g in your first statement in a scalar context, so the position of the digits to count is less than one, thus the value '4' was printed. Please, note that as long as your match didn't fail, your position changes

check this:

#!/usr/bin/perl
use strict;
use warnings;

my $a="  456 789 123 456 789  ";
my $count;
$count=$a =~ /\d+/g;
print "$count\n";    # output '1', position changes
$count=$a =~ /\d+/g;
print "$count\n";    # output '1' position changes

$count = () = $a =~ /\d+/g;
print "$count\n";  # output '3'

my @a = $a =~ /\d+/g;
$count = @a;
print "$count\n";
[download]

if you wanted to get '5', at the second print (a) remove the /g, then the second print gives you a '5', like this:

#!/usr/bin/perl
use strict;
use warnings;

my $a="  456 789 123 456 789  ";
my $count;
$count=$a =~ /\d+/;
print "$count\n";

$count = () = $a =~ /\d+/g;
print "$count\n";

my @a = $a =~ /\d+/g;
$count = @a;
print "$count\n";
[download]

(b) In another case, you can do this:

#!/usr/bin/perl
use strict;
use warnings;

my $a="  456 789 123 456 789  ";
my $count;
my $b=$a;
$count=$a =~ /\d+/g;
print "$count\n";

$count = () = $b =~ /\d+/g;
print "$count\n";

my @a = $b =~ /\d+/g;
$count = @a;
print "$count\n";
[download]

Thanks you for you detailed explanation :-)