#! perl -slw
use strict;
use Data::Dump qw[ pp ];

my @out;
while( <DATA> ) {
    chomp;
    my $n = 0;
    $out[ $n++ ] .= $_ for unpack '(A2)*', $_;
}

pp \@out;

__DATA__
abcdef
abcdef
abcdef
abcdef
[download]

Produces:

C:\test>junk.pl
["abababab", "cdcdcdcd", "efefefef"]
[download]

A variation on the theme:

#! perl
use Modern::Perl;
use Data::Dump;

my @array;

while (<DATA>)
{
    chomp;
    my @pairs = /(..)/g;
    $array[$_] .= $pairs[$_] for 0 .. $#pairs;
}

dd @array;

__DATA__
abcdef
abcdef
abcdef
abcdef
[download]

Output:

22:46 >perl 403_SoPW.pl
("abababab", "cdcdcdcd", "efefefef")

22:50 >
[download]

Hope that helps,

I assume in the second line of your "while" loop that you meant @pairs =~ /(..)/g; right?

ack Albuquerque, NM

No, I did mean =, for assignment.

On each iteration of the while loop, the default variable $_ is implicitly assigned the next line read from the DATA handle. This $_ variable becomes the implicit argument to chomp, and then it’s implicitly bound to the regex match.

So, the code I gave is equivalent to this:

while ($_ = <DATA>)
{
    chomp $_;
    my @pairs = $_ =~ /(..)/g;
    ...
[download]

but more compact and “Perlish”. See perlvar#General-Variables.

Hope that helps,

Athanasius <°(((>< contra mundum

Simple search

 [convert rows to columns] convert rows to columns -> convert rows to columns, whoops :)

 [conv row column] conv row column -> converting rows into column, How to convert a row structured text file into a column structed text file, Converting Column Into Row, how do i convert text file into a table having fixed columns and different rows

So perlintro, split, unpack, m//atch... The Perl Monks Guide to the Monastery

Don't forget to search

Hi,

there is something which jumped into my eye: The index of an array runs from 0 to scalar(@array) - 1, so you have to adjust the condition of your for loop.

Best regards
McA

I saw that, to. Also, you can't push to a sigle element of an array that I'm aware of. You have to push to an array. So the line push $arr[$cnt], $xox[$i]."".$xox[1+$i] I believe won't work. You need something like push @arr, $xox[$i]."".$xox[1+$i].

ack Albuquerque, NM

In recent Perl (since 5.14), you can push to an array reference. It is not autovivified, though; therefore,

perl -e '$x[0] = []; push $x[0], 1'
[download]

works, but

perl -e 'push $x[0], 1'
[download]

does not.
لսႽ† ᥲᥒ⚪⟊Ⴙᘓᖇ Ꮅᘓᖇ⎱ Ⴙᥲ𝇋ƙᘓᖇ