G'day atu,

Welcome to the monastery.

You have some syntax errors there (e.g. my $student = (...); my $student = (...);). Use the strict and warnings pragmata to get feedback from Perl: see my code below for usage.

I'm guessing you're probably after something like this:

#!/usr/bin/env perl -l

use strict;
use warnings;

use Data::Dumper;

my @classrooms;

my @students = (
    { studentName => 'John', studentSurname => 'Something',
        studentID => 9534, age => 12 },
    { studentName => 'Mary', studentSurname => 'Something2',
        studentID => 5489, age => 13 },
);

my %classroom = ( classroomID => 10, classroomName => 'classroom1' );

push @{$classroom{students}}, @students;

push @classrooms, \%classroom;

print 'Name of 1st student in 1st classroom: ',
        $classrooms[0]{students}[0]{studentName};
 
print 'The whole school:';
print Dumper \@classrooms;
[download]

Output:

Name of 1st student in 1st classroom: John
The whole school:
$VAR1 = [
          {
            'classroomName' => 'classroom1',
            'students' => [
                            {
                              'studentSurname' => 'Something',
                              'studentID' => 9534,
                              'studentName' => 'John',
                              'age' => 12
                            },
                            {
                              'studentSurname' => 'Something2',
                              'studentID' => 5489,
                              'age' => 13,
                              'studentName' => 'Mary'
                            }
                          ],
            'classroomID' => 10
          }
        ];
[download]

I'd recommend you look at "perldsc - Perl Data Structures Cookbook" which describes these types of structures in detail.

So, if I get you right, you want to have an array of classrooms, each classroom being a hash containing some information on the classroom and an array of students, each student being in turn a hash.

There are many ways to construct this structure, and the best way may vary depending on where your data is coming from. You might find it easier to start from the bottom (lower level structures) and make your way up.

You could start by creating a student list with something like this:

my @student_list;
push @student_list, { studentName => 'John', studentSurname=>'Somethin
+g',  studentID=>'9534', age=>'12' };
push @student_list, { studentName => 'Mary' ,studentSurname=>'Somethin
+g2',  studentID=>'5489', age=>'13' };
[download]

The @student_list array is now an array of anonymous hash refs (references to student hashes). Next, you want to create a classroom hash, which could be done as follows:

The structure now looks like this:

0  HASH(0x80355e98)
   'classroomID' => 10
   'classroomName' => 'classroom1'
   'students' => ARRAY(0x80359e18)
      0  HASH(0x8006c050)
         'age' => 12
         'studentID' => 9534
         'studentName' => 'John'
         'studentSurname' => 'Something'
      1  HASH(0x8032f958)
         'age' => 13
         'studentID' => 5489
         'studentName' => 'Mary'
         'studentSurname' => 'Something2'
[download]

The final step is to push a a ref to %classroom onto an array of classrooms:

To access the surname of the second student, one possible way:

 print $classrooms[0]{students}[1]{'studentSurname'}; # prints 'Someth
+ing2'
[download]

Or, if you prefer:

Something like this:

UPDATE: In my zest to copy the original code, I made a mistake in my code below. Thanks Laurent_R for pointing it out in the node below. Corrected code follows:

# your initial definitions here

# maybe a loop starts here
my $student;  # single student
my @students; # all students in 1 class

$student = {
    studentName => 'John',
    studentSurname=>'Something',
    studentID=>'9534',
    age=>'12'
};
push @students, $student;

# Eliminate loading next student below explicitly
# by using a loop to read from source file, DB, etc.
$student = {
    studentName => 'Mary',
    studentSurname=>'Something2',
    studentID=>'5489',
    age=>'13'
};
push @students, $student;

%classroom = (
    classroomID => 10,
    classroomName => 'classroom1',
    students => \@students
);

# Rinse, repeat
[download]

Hi VinsWorldcom,

I guess it's a typo, but this part in your code:

$student = (
    studentName => 'John',
    studentSurname=>'Something',
    studentID=>'9534',
    age=>'12'
);
push @students, $student;
[download]

probably does not work properly, as far as I can say. The value of $student is now 12 because you are assigning a list to a scalar, and you're then pushing 12 into @students.

You probably want either directly an hash ref like this:

$student = {
    studentName => 'John',
    studentSurname=>'Something',
    studentID=>'9534',
    age=>'12'
};
push @students, $student;
[download]

Or an hash on which you later take a ref:

%student = (
    studentName => 'John',
    studentSurname=>'Something',
    studentID=>'9534',
    age=>'12'
);
push @students, \%student;
[download]

You're right, I'm wrong. I've corrected my code in the node above (so as to not leave incorrect code there for posterity) and provided credit to you so your above correction doesn't seem misplaced.

Thanks!

One suggestion I would have is that, if your classrooms and students have unique IDs, you put them in a hash with that ID as the key, rather than an array. That will make accessing the data by those IDs simpler. Here's an example of creating such a structure, accessing its values in a couple of different ways, and adding to it:

#!/usr/bin/env perl
use strict; use warnings;

my %classroom = (
    10 => {
        classroomName    => 'classroom1',
        student          => {
            9534   => {
                studentName    => 'John',
                studentSurname => 'Doe',
                age            => '12',
            }
        },
    },
);

my $room = 10; my $kid = 9534;
print <<END;
Student $kid in room $classroom{$room}{classroomName} is 
$classroom{$room}{student}{$kid}{studentName} $classroom{$room}{studen
+t}{$kid}{studentSurname},
who is age $classroom{$room}{student}{$kid}{age}.


END

# Add a classroom
$classroom{11} = { 
    classroomName => 'classroom2',
};

# Add a student to new classroom
$classroom{11}{student}{5489} = {
    studentName    => 'Mary',
    studentSurname => 'Smith',
    age            => 13,
};

# Add a student to old classroom
$classroom{10}{student}{3456} = {
    studentName    => 'Jim',
    studentSurname => 'Baker',
    age            => 14,
};

# Print structure
print "Students listed by classroom\n";
for my $cid (keys %classroom) {
    print "Classroom ID $cid, name $classroom{$cid}{classroomName}\n";
    for my $sid (keys %{$classroom{$cid}{student}}) {
        my $student = $classroom{$cid}{student}{$sid}; #for less typin
+g
        print '   ', join ' ', $sid,
            @{$student}{qw/studentName studentSurname age/};
        print "\n";
    }
}

# Print raw structure
use Data::Dumper;
print "\n\n", Dumper %classroom;
[download]

Data::Dump output

my $classss = {
  classroom => {
    students => [
      { age => 0, fn => 0, id => 0, ln => 0 },
      { age => 1, fn => 1, id => 1, ln => 1 },
    ],
  },
};
[download]

rehohy output( Re: Google decoder (how to access hash values, perl dereferencing string xpaths data dumper ) )

my %classrooms;
$classrooms{classroom}{students}[0]{ln}
   = 0; #d3

$classrooms{classroom}{students}[0]{id}
   = 0; #d3

$classrooms{classroom}{students}[0]{age}
   = 0; #d3

$classrooms{classroom}{students}[0]{fn}
   = 0; #d3

$classrooms{classroom}{students}[1]{ln}
   = 1; #d3

$classrooms{classroom}{students}[1]{id}
   = 1; #d3

$classrooms{classroom}{students}[1]{age}
   = 1; #d3

$classrooms{classroom}{students}[1]{fn}
   = 1; #d3
[download]

See also references quick reference, hashes are curly
Re: How to traverse a two dimentional array in a constructor?, Re: Parsing SOAP::Lite results,, Re: Trouble accessing Hash of Arrays (troubleshooting basics),
Re^5: Combining 3 files,

corerection

my @classrooms =
(
  {
    classname => 1,
    students  => [
                   { age => 0, fn => 0, id => 0, ln => 0 },
                   { age => 1, fn => 1, id => 1, ln => 1 },
                 ],
  },
)
;
my @classrooms;
$classrooms[0]{students}[0]{ln}
   = 0; #d3

$classrooms[0]{students}[0]{id}
   = 0; #d3

$classrooms[0]{students}[0]{age}
   = 0; #d3

$classrooms[0]{students}[0]{fn}
   = 0; #d3

$classrooms[0]{students}[1]{ln}
   = 1; #d3

$classrooms[0]{students}[1]{id}
   = 1; #d3

$classrooms[0]{students}[1]{age}
   = 1; #d3

$classrooms[0]{students}[1]{fn}
   = 1; #d3

$classrooms[0]{classname}
 = 1; #d1
[download]

A quick summary of all the wonderfully complete advice you have thus far received:

Look into Hash of Hashes, Hash of Arrays, Array of Hashes. Often abbreviated HoH, HoA, AoH.

There will likely be some time needed to absorb -- but well worth the effort.

My two cents and all that rot.

Thanks a lot! I will check them asap!

These terms are exactly equivalent.
Since these terms mean the same, we can “normalize” these terms to be the same text (classroom2 means number 11)

my $student = ( studentName => 'John', studentSurname=>'Something', studentID=>'9534', age=>'12', Class=>10 );

It would also be “ok” in an Excel spreadsheet to have: array like this:
”John”,”Something”,”9534”,”12”,”10”

A Perl Array of Hash is close to a C "Array of Struct" or even an Excel "line" when properly spaced although that might not be so apparent to many. There is sure to be some fancy translations between BIO101, Class VV, etc that will/can be done in an SQL database.