jasal has asked for the wisdom of the Perl Monks concerning the following question:

I am using LibXML and have nasty issue. My XML looks like this: 
<root>
<parameters>
<key name="Repetitions" value="500" />
<key name="Mode" value="COLD" />
...
</parameters>
</root>

[download]
I want to change "Repetitions" value in my code, then save the file. I have tried "setData" but it "Can't locate object method "setData"". What is the right method to select the correct key and then alter it?

Replies are listed 'Best First'.
Re: Modifying XML with LibXML
by choroba (Cardinal) on Nov 28, 2013 at 10:36 UTC
    For attributes, use setValue, not setData: 
    #!/usr/bin/perl
use warnings;
use strict;

use XML::LibXML;

my $xml = 'XML::LibXML'->load_xml( string => << '======' );
<root>
<parameters>
<key name="Repetitions" value="500" />
<key name="Mode" value="COLD" />
</parameters>
</root>
======

my $root = $xml->documentElement;
my ($value) = $root->findnodes('parameters/key/@value[.="500"]');
$value->setValue(501);
print $root->serialize;

    [download]

    Or, if you find it too verbose, here is the same in XML::XSH2:

    open file.xml ;
set /root/parameters/key/@value[.="500"] 501 ;
save :b ;

    [download]
    لսႽ† ᥲᥒ⚪⟊Ⴙᘓᖇ Ꮅᘓᖇ⎱ Ⴙᥲ𝇋ƙᘓᖇ
[reply]
[d/l]
[select]

      Playing around with XML::LibXML::Attribute objects is usually unnecessary. It's easier to select the element and then use getAttribute and setAttribute, or if you have a vaguely recent copy of XML::LibXML, just treat the element as a hashref...

      use strict;
use warnings;
use XML::LibXML 2;

my $xml = 'XML::LibXML'->load_xml(IO => \*DATA);

$_->{value}++
    for $xml->findnodes('//key[@name="Repetitions"]');

print $xml->toString;

__DATA__
<root>
<parameters>
<key name="Repetitions" value="500" />
<key name="Mode" value="COLD" />
...
</parameters>
</root>

      [download]
      use Moops; class Cow :rw { has name => (default => 'Ermintrude') }; say Cow->new->name
[reply]
[d/l]
[select]

Back to Seekers of Perl Wisdom