Re: Modifying XML with LibXML

For attributes, use setValue, not setData:

#!/usr/bin/perl
use warnings;
use strict;

use XML::LibXML;

my $xml = 'XML::LibXML'->load_xml( string => << '======' );
<root>
<parameters>
<key name="Repetitions" value="500" />
<key name="Mode" value="COLD" />
</parameters>
</root>
======

my $root = $xml->documentElement;
my ($value) = $root->findnodes('parameters/key/@value[.="500"]');
$value->setValue(501);
print $root->serialize;
[download]

Or, if you find it too verbose, here is the same in XML::XSH2:

open file.xml ;
set /root/parameters/key/@value[.="500"] 501 ;
save :b ;
[download]

لսႽ† ᥲᥒ⚪⟊Ⴙᘓᖇ Ꮅᘓᖇ⎱ Ⴙᥲ𝇋ƙᘓᖇ

Comment on Re: Modifying XML with LibXML Select or Download Code

Replies are listed 'Best First'.
Re^2: Modifying XML with LibXML by tobyink (Canon) on Nov 28, 2013 at 10:53 UTC
Playing around with XML::LibXML::Attribute objects is usually unnecessary. It's easier to select the element and then use `getAttribute` and `setAttribute`, or if you have a vaguely recent copy of XML::LibXML, just treat the element as a hashref... `use strict; use warnings; use XML::LibXML 2; my $xml = 'XML::LibXML'->load_xml(IO => \*DATA); $_->{value}++ for $xml->findnodes('//key[@name="Repetitions"]'); print $xml->toString; __DATA__ <root> <parameters> <key name="Repetitions" value="500" /> <key name="Mode" value="COLD" /> ... </parameters> </root>` [download] `use Moops; class Cow :rw { has name => (default => 'Ermintrude') }; say Cow->new->name`	[reply] [d/l] [select]

Replies are listed 'Best First'.

Re^2: Modifying XML with LibXML
by tobyink (Canon) on Nov 28, 2013 at 10:53 UTC

Playing around with XML::LibXML::Attribute objects is usually unnecessary. It's easier to select the element and then use getAttribute and setAttribute, or if you have a vaguely recent copy of XML::LibXML, just treat the element as a hashref...

use strict;
use warnings;
use XML::LibXML 2;

my $xml = 'XML::LibXML'->load_xml(IO => \*DATA);

$_->{value}++
    for $xml->findnodes('//key[@name="Repetitions"]');

print $xml->toString;

__DATA__
<root>
<parameters>
<key name="Repetitions" value="500" />
<key name="Mode" value="COLD" />
...
</parameters>
</root>
[download]

use Moops; class Cow :rw { has name => (default => 'Ermintrude') }; say Cow->new->name

[reply]
[d/l]
[select]