perl -e '10 .. 20 and print while <>' wordlist
[download]

Or

perl -e 'print for (<>)[9 .. 19]' wordlist
[download]

Thanks.
Works.
My hit-n-trial also worked out finally.


perl -e 'print ((`cat wordlist`)[60..70]);'
[download]

If you want to eliminate `cat wordlist`, you can use File::Slurp or do { local @ARGV='wordlist'; <> }.

Note that although many of them are elegant, all the techniques posted so far will read the entire input file. If you only need lines 60 to 70 out of a million line file, this is fairly wasteful.

The following example actually stops reading the file after the 70th line has been encountered:

perl -ne '$.<60 ? next : $.>70 ? last : print' wordlist.txt
[download]

If you actually need these lines in an array for some reason, you can do something like this:

perl -ne '$.<60 ? next : $.>70 ? last : push @arr, $_ }END{ print scal
+ar(@arr),"\n"' wordlist.txt
[download]

Note that although many of them are elegant, all the techniques posted so far will read the entire input file.

:) Path::Tiny::lines patch

use Path::Tiny  qw/ path /;
print path( 'wordlist' )->lines( { range => [ 60, 70] } );


sub Path::Tiny::lines {
    package Path::Tiny;
    my $self    = shift;
    my $args    = _get_args( shift, qw/binmode chomp count range/ );
    my $binmode = $args->{binmode};
    $binmode = ( ( caller(0) )[10] || {} )->{'open<'} unless defined $
+binmode;
    my $fh = $self->filehandle( { locked => 1 }, "<", $binmode );
    my $chomp = $args->{chomp};
    # XXX more efficient to read @lines then chomp(@lines) vs map?
 
    if( my $count = $args->{count} ){ ## count trumps/clobbes range
        $args->{range} = [ 0, $count ];
    }

    if( my @range = @{ $args->{range} || [] } ){
        my( $start, $end ) = @range;
        $start ||= 0;
        defined $end or $end = -1;
        my @result;
        local $.;
        while ( my $line = <$fh> ) {
            next if $. < $start;
            $line =~ s/(?:\x{0d}?\x{0a}|\x{0d})$// if $chomp;
            push @result, $line ;
            last if $. >= $end;
        }
        return @result;
    }
    elsif ($chomp) {
        return map { s/(?:\x{0d}?\x{0a}|\x{0d})$//; $_ } <$fh>; ## no 
+critic
    }
    else {
        return wantarray ? <$fh> : ( my $count =()= <$fh> );
    }
}
[download]

This doesn't count as a one-liner until the method is included in the CPAN version of Path::Tiny. Hint, hint... ;-)

use Moops; class Cow :rw { has name => (default => 'Ermintrude') }; say Cow->new->name

perl -ne 'print if ($. >= 10 and $. <=20 )' filename.ext
[download]

That's right. Tried it already using $.
Just wanted to do something via a list context as a one-liner.
Learning purpose you can say. Anyway, thanks a lot.

perl -ne 'print if 60..70;' file.txt
[download]

That's good one.
Correct me if I'm wrong. Hope this is using $_ and not $., since a while loop is roaming around the statement with perl -n .
So what would be the expanded form of this statement?

as pointed by ambrus in the chat $. come in place because of flip flop operator

If either operand of scalar ".." is a constant expression, that operan
+d is considered true if it is equal (== ) to the current input line n
+umber (the $. variable).
[download]


HtH
L*
There are no rules, there are no thumbs..
Reinvent the wheel, then learn The Wheel; may be one day you reinvent one of THE WHEELS.

It is using implicitly both $. and $_. A possible expanded form could be:

perl -ne 'print $_ if $. >= 60 and $. <= 70' file.txt
[download]

or, expanding further:

perl -e 'while (<>) {print $_ if $. >= 60 and $. <= 70;}' file.txt
[download]

use Path::Tiny qw/ path /;
print(  (path('wordlist')->lines)[60..70] );
[download]

This will do it, and do it efficiently:

perl -ne 'while(<>) { next if $. < 60; last if $. > 70; print; }' 
wordlist
[download]

The logic’s clear enough and it fits on one line (although I word-wrapped it for clarity):   loop if we’re not at the right starting position, break out of the loop if we’re past it, otherwise print a line.   Virtually no memory is consumed and the loop does not read the whole file.