No need to futz around with map. Just push the contents of @{$data2} onto @{$data1}.

Using push:

push @$data1, @$data2;

Result:


[
          {
            'DATE' => '2009-05-05',
            'NAME' => 'PAUL DY',
            'NUMBER' => '00001'
          },
          {
            'NAME' => 'ANTHONY RD',
            'NUMBER' => '00003',
            'DATE' => '2012-01-07'
          },
          {
            'NUMBER' => '00023',
            'NAME' => 'RUTH RD',
            'DATE' => '2018-01-07'
          },
          {
            'CODE' => 'X11'
          }
        ]
[download]


Looking for this:


[
{
   'NAME' => 'PAUL DY',
   'DATE' => '2009-05-05',
   'NUMBER' => '00001',
   'CODE' => 'X11',
 },
   {
   'NAME' => 'ANTHONY RD',
   'DATE' => '2012-01-07',
   'NUMBER' => '00003',
   'CODE' => 'X11',
 },
  {
   'NAME' => 'RUTH RD',
   'DATE' => '2018-01-07',
   'NUMBER' => '00023',
   'CODE' => 'X11',
 },
 
 ]
[download]


Thanks!

One way (update: see the Perl Data Structures Cookbook):

c:\@Work\Perl\monks>perl
use strict;
use warnings;

use Data::Dumper;

my $data1 = [
{
   'NAME' => 'PAUL DY',
   'DATE' => '2009-05-05',
   'NUMBER' => '00001',

 },
   {
   'NAME' => 'ANTHONY RD',
   'DATE' => '2012-01-07',
   'NUMBER' => '00003',
 },
  {
   'NAME' => 'RUTH RD',
   'DATE' => '2018-01-07',
   'NUMBER' => '00023',
 },

 ];

my $data2 = [
  {
    'CODE' => 'X11',
  }
];

foreach my $hashref (@$data1) {
  %$hashref = (%$hashref, %{ $data2->[0] });
  }

print Dumper $data1;

__END__
$VAR1 = [
          {
            'NAME' => 'PAUL DY',
            'DATE' => '2009-05-05',
            'CODE' => 'X11',
            'NUMBER' => '00001'
          },
          {
            'NAME' => 'ANTHONY RD',
            'DATE' => '2012-01-07',
            'CODE' => 'X11',
            'NUMBER' => '00003'
          },
          {
            'NAME' => 'RUTH RD',
            'DATE' => '2018-01-07',
            'CODE' => 'X11',
            'NUMBER' => '00023'
          }
        ];
[download]

Update 1: Note that using this method, if there is a key in the hash referent of the single element of the  $data2 array referent that is the same as one in a hash referent of any  $data1 array referent, the value of the former will silently overwrite the value of the latter. (Update: For instance, see what happens if  $data2 happens to be
    my $data2 = [ { 'CODE' => 'X11',  'NAME' => 'JONES', } ];
instead. (Update: This exact problem is discussed more clearly in the FAQ referenced by BillKSmith here.))

Update 2: Here's a testing framework for playing around with other approaches. See Test::More, Test::NoWarnings.

Read more... (2 kB)

---

Give a man a fish:  <%-{-{-{-<

You are merging the hash in $data2 with each of the hashes in $data1. Read the FAQ.

perldoc -q "How do I merge two hashes?"
[download]

Bill

while(my($k,$v)=each %{$data2->[0]}){
  $_->{$k} = $v for @$data1;
}
[download]

for (my($k,$v)=each %{$data2->[0]}){
  $_->{$k} = $v for @$data1;
}
[download]

That works for a single key/value element in $data2->[0], but given that it can work for only a single element, why not use the ocularly even easier

my ($k,$v) = %{$data2->[0]};

$_->{$k} = $v for @$data1;
[download]

c:\@Work\Perl\monks>perl
use strict;
use warnings;

use Data::Dumper;

my $data1 = [
  { 'NAME'   => 'PAUL DY',
    'DATE'   => '2009-05-05',
    'NUMBER' => '00001',
    },
  { 'NAME'   => 'ANTHONY RD',
    'DATE'   => '2012-01-07',
    'NUMBER' => '00003',
    },
  { 'NAME'   => 'RUTH RD',
    'DATE'   => '2018-01-07',
    'NUMBER' => '00023',
    },
  ];

my $data2 = [ { 'CODE' => 'X11', 'X' => 'Y', } ];

for (my($k,$v)=each %{$data2->[0]}){
  $_->{$k} = $v for @$data1;
}

print Dumper $data1;

__END__
$VAR1 = [
          {
            'NAME' => 'PAUL DY',
            'X' => 'Y',
            'DATE' => '2009-05-05',
            'NUMBER' => '00001'
          },
          {
            'NAME' => 'ANTHONY RD',
            'X' => 'Y',
            'DATE' => '2012-01-07',
            'NUMBER' => '00003'
          },
          {
            'NAME' => 'RUTH RD',
            'X' => 'Y',
            'DATE' => '2018-01-07',
            'NUMBER' => '00023'
          }
        ];
[download]

---

Give a man a fish:  <%-{-{-{-<

for (my($k,$v)=each %{$data2->[0]}){

You may need to use while in place of for to get all the value in %{$data2->[0]}

for my $hash1  (@{$data1}){
    for my $hash2 (@{$data2}){
        for my $key (keys %$hash2){
            $hash1->{$key}=$hash2->{$key};
        }
    }
}
print Dumper $data1;
[download]

It accommodates for multiple key/values in data2.

It accommodates multiple hashes in  $data2 with each hash having multiple key/values! This exceeds the implied requirement of the OP, but I find that requirements tend to expand spontaneously in these situations anyway.

I was a bit daunted by the time-complexity of the triple nesting of your solution. I tried to come up with some alternatives. I think these all work, but neither your solution nor any of mine have been thoroughly tested by me. Unfortunately, I think the big-Os of all these solutions, yours and mine, are going to turn out to be exactly the same!

foreach my $hashref (@$data1) {
  %$hashref = (%$hashref, %$_) for @$data2;
  }

for my $hash1 (@$data1) {
  @{ $hash1 }{ keys %$_ } = values %$_ for @$data2;
  }

foreach my $hash1 (@$data1) {
  for my $hash2 (@$data2) {
    map { $hash1->{$_} = $hash2->{$_} } keys %$hash2;
    }
  }

for my $hash1 (@$data1) {
  for my $hash2 (@$data2) {
    while (my ($k2, $v2) = each %$hash2) {
      $hash1->{$k2} = $v2;
      }
    }
  }
[download]

---

Give a man a fish:  <%-{-{-{-<