When you use a filehandle in a list context (e.g. your line @second_file{map { unpack 'A*', $_ } <$b_fh>} = ();) it reads the entire contents splitting it into lines (modulo $/ of course; see perlvar). The next time you use that same filehandle, since everything's been read from the file it's just going to return undef because it's at the end of the file. You need to either close and re-open it, or use seek to set the file pointer back at the beginning of the file (at which point reading from it will again return the lines).

@second_file{map { unpack 'A*', $_ } <$b_fh>} = ();
seek( $b_fh, 0, 0 ); ## Reset $b_fh back to the beginning
[download]

That aside, if you're on a *NIX-y system you might be interested in the diff or cmp commands instead.

I didn't test this and I'm sure there is bound to be some mistake somewhere, but be that as it may, consider this:

#!/usr/local/bin/perl

use strict;
use warnings;

my $a_file;  # you need an initial value for these names!
my $b_file;  # in case the if statement doesn't work

# quit unless we have the correct number of command-line args
if (@ARGV != 5) {
    print "\nUsage: $0 new_filename orig_filename domain new_tools ori
+g_tools\n";
    exit(-1);
}

#  args
my ( $new_filename, 
     $orig_filename,
     $domain,
     $new_tools,
     $orig_tools ) = @ARGV;
my $psconfig = "psconfig.sh";

if ($new_filename eq $psconfig) {
    $a_file = "/directory/$new_filename" ;
    $b_file = "/directory/$orig_filename" ;
}

open my $a_fh, '<', $a_file  or die "file error $a_file: $!";
open my $b_fh, '<', $b_file  or die "file error $b_file: $!";

my %first_file  = map { chomp; $_ => 1}<$a_fh>;
my %second_file = map { chomp; $_ => 1}<$b_fh>;

print "\n--------------------------------------------\n";
print "Output from $new_tools $domain $new_filename\n";
print "--------------------------------------------\n";


foreach (keys %first_file) {
    print "$_\n" unless exists $second_file{$_};
}

print "\n--------------------------------------------\n";
print "Output from $orig_tools $domain $orig_filename\n";
print "--------------------------------------------\n";


foreach (keys %second_file) {
    print "$_\n" unless exists $first_file{$_};
}
[download]

I am not sure what you are trying to accomplish with the unpack A* code?

I think you're right that unpack is intended to chomp the newline (and maybe all whitespace?) from the end of each line.

c:\@Work\Perl\monks>perl -wMstrict -MData::Dump -le
"my $s = qq{abc defg hi  \t  \n};
 my $t = unpack 'A*', $s;
 dd $t;
"
"abc defg hi"
[download]

(It's also unclear why chomp-ing would be necessary since lines are print-ed with a newline appended; no newline is appended in the OPed code, but maybe that potential problem was obscured by the fact that nothing was ever printed!)

Note that the keys (lines) of each file will be printed in random order.

---

Give a man a fish:  <%-{-{-{-<

I think you are correct about the intent of unpack. However this is a bad way to do it, if that is the intent. There might also be some issue related to UTF-8 filenames? But again this is not the "right way".

I chomped the input lines and added back in a platform specific line ending in the print because in general, I don't store line endings in data structures because I strive for multi-platform code.

Yes, foreach (keys %first_file) {} could be: foreach (sort keys %first_file) {}

Thank You. I guess I was overthinking what I wanted to do which was to get the diff between both files output. I modified my code according to the changes you had posted and it is working as I expected.

The loop

while (<$a_fh>) {
    print unless exists $second_file{unpack 'A*', $_};
}
[download]

eats up the whole file. Maybe your intention was like:

while (<$file_a>) {
    unless (exists $h{unpack 'A*', $_}) {
        print;
    } else {
        last;
    }
}
[download]

And then there is of course the other issue with using <$file_x> in list context as already described by Fletch and the questionable use of unpack.

-jo