#!/usr/bin/perl
use warnings;
use strict;

use experimental 'signatures';
use Syntax::Construct qw{ // };

sub show ($arg) { $arg // 'undef' }

use Test::More;
use Test::Exception;

throws_ok { show() } qr/Too few arguments/;

done_testing();
[download]

My question was about optional arguments.

Greetings,
-jo

$gryYup$d0ylprbpriprrYpkJl2xyl~rzg??P~5lp2hyl0p$

Oh, sorry, I didn't get it.

Why do you need it?

It seems you don't want an optional argument with a default value, you want a subroutine that knows whether setting the default value was triggered. It's hard to do it with just the optional argument, as it's a single value, but you're interested in two values: the value itself and the boolean telling whether the default value was triggered. Both your solutions introduce such a value (whether it's the scalar @_ or the additional lexical variable). I'm not sure which one I'd prefer, but I'd probably add a comment to both of them.

map{substr$_->[0],$_->[1]||0,1}[\*||{},3],[[]],[ref qr-1,-,-1],[{}],[sub{}^*ARGV,3]

The rule of thumb is to use a default which is defined. °

Using undef as default should be redundant and will force you to check @_ - if still possible (untested)

Sorry, your code is longish (aka TLDR), if I didn't get it right, please consider condensing it to the relevant part.

This question could be actually very relevant if there is a real use case! P5P is considering to drop the population of @_ when signatures are used.

update

°) not

# Standard signature with optional second arg.

sub sig_std ($what, $arg=undef) {
[download]

P5P is considering to drop the population of @_ when signatures are used

But only after alternative facilities for argument instrospection have been provided. See the proposal on the p5p mailing list.

In particular, in

sub foo($x,  ??$has_y, $y = 0) { ... }
[download]

$has_y is true if and only if a second arg is passed to the sub.

Dave.

sub foo($x,  ??$has_y, $y = 0) { ... }
[download]

Great! That's it. (Or better: Will be)

Greetings,
-jo

$gryYup$d0ylprbpriprrYpkJl2xyl~rzg??P~5lp2hyl0p$

The use case I have in mind is a combined getter/setter for a perl object. Return the value when called without an additional arg, set the value when called with an arg. A call with an undefined arg clears the attribute - just like in my example.

Maybe that's not a real world use case - I'm just playing with things.

Greetings,
-jo

$gryYup$d0ylprbpriprrYpkJl2xyl~rzg??P~5lp2hyl0p$

> combined getter/setter ... Return the value when called without an additional arg,

from my experience are mutators written in a way to always return the value.

> A call with an undefined arg clears the attribute - just like in my example.

OK ... but in that case why do you have a default value at all?

Anyway, if you want to allow to set to undef and don't wanna introspect @_ , then you're stuck in a kind of semipredicate problem.

Such problems can be solved in Perl by setting a new "impossible"° object MISSING as default, like

use constant MISSING => bless {}, "MyPackg::__Missing__"

and later

sub mutator ($value = MISSING) { ...BODY... }

(untested)

If you see that an arguments equals to that "impossible" value blessed into your own private namespace below "MyPackg", you can be sure that it wasn't used by accident.

HTH! :)

update

clearer rewording, clearer code

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery}

°) of course it's possible that such a value is used, but extremely unlikely without intend.

Using LanX's suggestion in Re^3: Distinguish between missing and undefined arguments with subroutine signatures (semipredicate problem), I finally found a practicable solution to my problem.

# Unique catcher for a missing argument
use constant MISSING => bless {}, __PACKAGE__ . '::__missing__';

# Helper sub, that either checks its argument against the catcher
# or otherwise returns the catcher itself.
sub missing {
    @_ ? $_[0] && $_[0] eq MISSING : MISSING;
}

# To be used with signatures in various places:
sub foo ($self, $val=missing) {
    if (missing $val) {
        # getter
    } else {
        # setter
    }
}
[download]

Thanks, Rolf!

Your Welcome! :)

But I suppose you don't want the sub missing() to be available as method the way ->foo() is?

And while the MISSING object is a nice workaround for the semi-predicate problem, I still think it's an overkill here.

Like I said you could just slurp into @val and have the full functionality, with less code:

use strict;
use warnings;
use experimental "signatures";
use Carp;

{
    package BLA;

    sub new ($class,@properties) {
        return bless {@properties}, $class;
    }


    sub foo ($self, @val) {
        unless (@val){                  # getter
            return $self->{foo}
        } elsif (@val == 1) {           # setter
            return $self->{foo} = $val[0];
        } else {                        # ERROR
            local $" = ",";
            Carp::croak "Too many arguments for method 'BLA->foo(@val)
+'";
        }
    }
}




my $x = BLA->new(foo=>42);

warn "getter:", $x->foo;
warn "setter:", $x->foo(666);
warn "getter:", $x->foo;
warn "error:",  $x->foo(42,666);
[download]

-*- mode: compilation; default-directory: "d:/tmp/pm/" -*-
Compilation started at Fri Jan  8 21:39:32

C:/Perl_524/bin\perl.exe -w d:/tmp/pm/missing_param.pl 
getter:42 at d:/tmp/pm/missing_param.pl line 31.
setter:666 at d:/tmp/pm/missing_param.pl line 32.
getter:666 at d:/tmp/pm/missing_param.pl line 33.
Too many arguments for method 'BLA->foo(42,666)' at d:/tmp/pm/missing_
+param.pl line 34.

Compilation exited abnormally with code 255 at Fri Jan  8 21:39:33
[download]

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery}

updates

improved code with croak and better error message

But I suppose you don't want the sub missing() to be available as method the way ->foo() is?

That doesn't harm at all. Calling $obj->missing just returns false, which is correct :-)

However, your objection discovered a flaw in my approach. The missing sub needs to be prototyped to go one step further: multiple optional arguments. And then slurping starts hurting :-)

This leads to:

#!/usr/bin/perl

use v5.16;
use warnings FATAL => 'all';

package Foo;
use experimental 'signatures';
use constant MISSING => bless {}, __PACKAGE__ . '::__missing__';

sub missing :prototype(;$) {
    @_ ? $_[0] && $_[0] eq MISSING : MISSING;
}

sub new ($class) {
    bless {}, $class;
}

sub foo ($self, $foo=missing, $bar=missing) {
    say "foo is missing" if missing $foo;
    say "bar is missing" if missing $bar;
}

package main;

my $foo = Foo->new;
say "none:";
$foo->foo;
say "one:";
$foo->foo(1);
say "two:";
$foo->foo(1, 2);
print "\n";
say 'object foo is not missing' unless $foo->missing;

__DATA__
none:
foo is missing
bar is missing
one:
bar is missing
two:

object foo is not missing
[download]

Greetings,
-jo

$gryYup$d0ylprbpriprrYpkJl2xyl~rzg??P~5lp2hyl0p$